blob: a72e71fb43699e628be4aa55fb54709ae47336e9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYTHON_TESTED=( python3_{10..12} pypy3 )
PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
inherit distutils-r1 pypi
DESCRIPTION="Thin-wrapper around the mock package for easier use with pytest"
HOMEPAGE="
https://github.com/pytest-dev/pytest-mock/
https://pypi.org/project/pytest-mock/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
RDEPEND="
>=dev-python/pytest-6[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
test? (
$(python_gen_cond_dep '
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
' "${PYTHON_TESTED[@]}")
)
"
distutils_enable_tests pytest
src_prepare() {
# obsolete, upst. e2016928db1147a2a46de6ee9fa878ca0e9d8fc8
sed -i -e '/import py\.code/d' tests/test_pytest_mock.py || die
distutils-r1_src_prepare
}
python_test() {
if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
einfo "Skipping tests on ${EPYTHON}"
return
fi
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=pytest_mock,pytest_asyncio.plugin
local EPYTEST_DESELECT=()
if has_version dev-python/mock; then
EPYTEST_DESELECT+=(
tests/test_pytest_mock.py::test_standalone_mock
)
fi
epytest --assert=plain
}
|