blob: dd007e5da5cb19a30119f6ff3532d4292caa0901 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..13} )
PYTHON_REQ_USE="ssl(+)"
inherit distutils-r1 pypi
DESCRIPTION="Python FTP server library"
HOMEPAGE="
https://github.com/giampaolo/pyftpdlib/
https://pypi.org/project/pyftpdlib/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
IUSE="examples ssl"
RDEPEND="
ssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
"
BDEPEND="
test? (
dev-python/psutil[${PYTHON_USEDEP}]
dev-python/pyopenssl[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
python_test() {
rm -rf pyftpdlib || die
# Some of these tests tend to fail
local EPYTEST_DESELECT=(
# fail because they process sys.argv and expect program args
# rather than pytest args, sigh
test/test_misc.py
# TODO
test/test_functional_ssl.py::TestFtpListingCmdsTLSMixin::test_nlst
)
# Tests fail with TZ=GMT, see https://bugs.gentoo.org/666623
local -x TZ=UTC+1
# Skips some shoddy tests plus increases timeouts
local -x TRAVIS=1
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest --pyargs pyftpdlib
}
python_install_all() {
if use examples; then
docinto examples
dodoc -r demo/.
docompress -x /usr/share/doc/${PF}/examples
fi
distutils-r1_python_install_all
}
|