blob: e997c2e9c7d1973c85cf9ee8b48f73ee084a2212 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_P="opentelemetry-python-${PV}"
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( python3_{11..13} )
inherit distutils-r1 pypi
DESCRIPTION="OpenTelemetry Semantic Conventions"
HOMEPAGE="
https://opentelemetry.io/
https://pypi.org/project/opentelemetry-sdk/
https://github.com/open-telemetry/opentelemetry-python/
"
SRC_URI="
https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S="${WORKDIR}/${MY_P}/${PN}"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 arm64 x86"
BDEPEND="
test? (
dev-python/asgiref[${PYTHON_USEDEP}]
dev-python/attrs[${PYTHON_USEDEP}]
dev-python/deprecated[${PYTHON_USEDEP}]
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/importlib-metadata[${PYTHON_USEDEP}]
dev-python/iniconfig[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
dev-python/pluggy[${PYTHON_USEDEP}]
dev-python/py-cpuinfo[${PYTHON_USEDEP}]
dev-python/py[${PYTHON_USEDEP}]
dev-python/tomli[${PYTHON_USEDEP}]
dev-python/typing-extensions[${PYTHON_USEDEP}]
dev-python/wrapt[${PYTHON_USEDEP}]
dev-python/zipp[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_prepare() {
default
# Use the same version with all opentelemetry components
# https://github.com/gentoo/gentoo/pull/35962#issuecomment-2025466313
sed -i -e "s/\(__version__ =\) .*/\1 \"${PV}\"/" src/opentelemetry/semconv/version.py || die
}
python_test() {
cp -a "${BUILD_DIR}"/{install,test} || die
local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
for dep in opentelemetry-api opentelemetry-sdk tests/opentelemetry-test-utils ; do
pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
distutils_pep517_install "${BUILD_DIR}"/test
popd >/dev/null || die
done
epytest
}
|