blob: 6a01b59dbefbe5c310412fd768a3e949355d5e1f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=scikit-build-core
PYTHON_COMPAT=( python3_{10..13} )
inherit cmake distutils-r1
DESCRIPTION="Tiny and efficient C++/Python bindings"
HOMEPAGE="
https://github.com/wjakob/nanobind
https://pypi.org/project/nanobind/
"
SRC_URI="
https://github.com/wjakob/nanobind/archive/refs/tags/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~riscv"
DEPEND="
>=dev-cpp/robin-map-1.3.0
"
RDEPEND="
${DEPEND}
"
BDEPEND="
$(python_gen_cond_dep '
dev-python/typing-extensions[${PYTHON_USEDEP}]
' 3.10)
"
EPYTEST_XDIST=1
distutils_enable_tests pytest
src_prepare() {
local PATCHES=(
# simplified version of https://github.com/wjakob/nanobind/pull/718
"${FILESDIR}/${PN}-2.0.0-parallel-build.patch"
)
cmake_src_prepare
PATCHES=()
distutils-r1_src_prepare
}
src_configure() {
# XXX: nanobind installs a CMake config file which by default passes -Os
# We currently patch around it in dev-python/pyopencl. In future, we
# may want to add some override with Gentoo specific environment vars.
DISTUTILS_ARGS=(
-DNB_CREATE_INSTALL_RULES=ON
-DNB_USE_SUBMODULE_DEPS=OFF
-DNB_TEST=OFF
)
}
python_test() {
local mycmakeargs=(
-DNB_CREATE_INSTALL_RULES=OFF
-DNB_USE_SUBMODULE_DEPS=OFF
-DNB_TEST=ON
)
cmake_src_configure
cmake_src_compile
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
cd "${BUILD_DIR}/tests" || die
epytest
}
|
