blob: 5724971667107fc9c57ad9fd7cad8348551474a2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 2019-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=flit
PYTHON_COMPAT=( python3_{10..12} pypy3 )
inherit distutils-r1 pypi
DESCRIPTION="Simplified packaging of Python modules"
HOMEPAGE="https://github.com/pypa/flit https://flit.readthedocs.io/"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~mips ~x86"
RDEPEND="
dev-python/docutils[${PYTHON_USEDEP}]
>=dev-python/flit-core-${PV}[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/tomli-w[${PYTHON_USEDEP}]
"
BDEPEND="${RDEPEND}
sys-apps/grep
test? (
dev-python/pip[${PYTHON_USEDEP}]
dev-python/responses[${PYTHON_USEDEP}]
dev-python/testpath[${PYTHON_USEDEP}]
)
"
EPYTEST_DESELECT=(
# requires Internet
tests/test_config.py::test_invalid_classifier
# failing due to Gentoo pip patches
tests/test_install.py::InstallTests::test_install_data_dir
tests/test_install.py::InstallTests::test_install_module_pep621
tests/test_install.py::InstallTests::test_symlink_data_dir
tests/test_install.py::InstallTests::test_symlink_module_pep621
)
distutils_enable_tests pytest
distutils_enable_sphinx doc \
dev-python/sphinxcontrib-github-alt \
dev-python/pygments-github-lexers \
dev-python/sphinx-rtd-theme
src_prepare() {
# make sure system install is used
rm -r flit_core || die
distutils-r1_src_prepare
}
|