summaryrefslogtreecommitdiff
path: root/dev-python/flask-gravatar/flask-gravatar-0.5.0-r2.ebuild
blob: 95e8deca89d93cd62990aa43cb119f0e3d3350ab (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
PYPI_NO_NORMALIZE=1
PYPI_PN="Flask-Gravatar"

inherit distutils-r1 pypi

DESCRIPTION="Small extension for Flask to make usage of Gravatar service easy"
HOMEPAGE="
	https://github.com/zzzsochi/Flask-Gravatar/
	https://pypi.org/project/Flask-Gravatar/
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~arm64 x86"

RDEPEND="
	<dev-python/flask-3[${PYTHON_USEDEP}]
"

distutils_enable_tests pytest

src_prepare() {
	sed -i -e '/pytest-runner/d' setup.py || die
	sed -e 's:--pep8::' \
		-e 's:--cov=flask_gravatar --cov-report=term-missing::' \
		-i pytest.ini || die
	distutils-r1_src_prepare
}

python_test() {
	cd tests || die
	epytest
}