blob: 2305dae7cb5229c4161e9b41294ffcb8acbc66e4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..11} pypy3 )
inherit distutils-r1
DESCRIPTION="Bash tab completion for argparse"
HOMEPAGE="
https://github.com/kislyuk/argcomplete/
https://pypi.org/project/argcomplete/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
IUSE="test"
RESTRICT="!test? ( test )"
# pip is called as an external tool
BDEPEND="
test? (
app-shells/fish
app-shells/tcsh
dev-python/pexpect[${PYTHON_USEDEP}]
>=dev-python/pip-19
)
"
src_prepare() {
sed -i -e 's:timeout=5:timeout=30:' test/test.py || die
distutils-r1_src_prepare
}
src_test() {
# workaround new readline defaults
echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
local -x INPUTRC="${T}"/inputrc
distutils-r1_src_test
}
python_test() {
"${EPYTHON}" test/test.py -v || die
}
|
