blob: c41a6ddc6fce1a509ca69deabaf9b5032cbc0e35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..12} )
inherit cmake llvm llvm.org python-any-r1
DESCRIPTION="OpenCL C library"
HOMEPAGE="https://libclc.llvm.org/"
LICENSE="Apache-2.0-with-LLVM-exceptions || ( MIT BSD )"
SLOT="0"
KEYWORDS="amd64 ~arm64 ~riscv ~x86"
IUSE="+spirv video_cards_nvidia video_cards_r600 video_cards_radeonsi"
LLVM_MAX_SLOT=17
BDEPEND="
${PYTHON_DEPS}
|| (
(
sys-devel/clang:17
spirv? ( dev-util/spirv-llvm-translator:17 )
)
(
sys-devel/clang:16
spirv? ( dev-util/spirv-llvm-translator:16 )
)
(
sys-devel/clang:15
spirv? ( dev-util/spirv-llvm-translator:15 )
)
(
sys-devel/clang:14
spirv? ( dev-util/spirv-llvm-translator:14 )
)
(
sys-devel/clang:13
spirv? ( dev-util/spirv-llvm-translator:13 )
)
)
"
LLVM_COMPONENTS=( libclc )
llvm.org_set_globals
llvm_check_deps() {
if use spirv; then
has_version -b "dev-util/spirv-llvm-translator:${LLVM_SLOT}" ||
return 1
fi
has_version -b "sys-devel/clang:${LLVM_SLOT}"
}
pkg_setup() {
llvm_pkg_setup
python-any-r1_pkg_setup
}
src_configure() {
local libclc_targets=()
use spirv && libclc_targets+=(
"spirv-mesa3d-"
"spirv64-mesa3d-"
)
use video_cards_nvidia && libclc_targets+=(
"nvptx--"
"nvptx64--"
"nvptx--nvidiacl"
"nvptx64--nvidiacl"
)
use video_cards_r600 && libclc_targets+=(
"r600--"
)
use video_cards_radeonsi && libclc_targets+=(
"amdgcn--"
"amdgcn-mesa-mesa3d"
"amdgcn--amdhsa"
)
[[ ${#libclc_targets[@]} ]] || die "libclc target missing!"
libclc_targets=${libclc_targets[*]}
local mycmakeargs=(
-DLIBCLC_TARGETS_TO_BUILD="${libclc_targets// /;}"
)
cmake_src_configure
}
|