blob: 77d02b80751bf5af397b5641edb8bf22deaa0191 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit go-module systemd tmpfiles
GIT_COMMIT=c9063a0dc
DESCRIPTION="Highly-available key value store for shared configuration and service discovery"
HOMEPAGE="https://github.com/etcd-io/etcd"
SRC_URI="https://github.com/etcd-io/etcd/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://dev.gentoo.org/~zmedico/dist/${P}-deps.tar.xz"
LICENSE="Apache-2.0"
LICENSE+=" BSD BSD-2 MIT"
SLOT="0"
KEYWORDS="~amd64 ~loong ~riscv"
IUSE="doc +server"
COMMON_DEPEND="server? (
acct-group/etcd
acct-user/etcd
)"
DEPEND="${COMMON_DEPEND}"
RDEPEND="${COMMON_DEPEND}"
# Tests fail with this error:
# fatal error: checkptr: unsafe pointer conversion
RESTRICT="test"
PATCHES=("${S}/go-mod-sum.patch")
src_prepare() {
export GO_BUILD_FLAGS="-v -x"
default
sed -e "s|GIT_SHA=.*|GIT_SHA=${GIT_COMMIT}|" \
-i "${S}"/build.sh || die
sed -e 's:\(for p in \)shellcheck :\1 :' \
-e 's:^ gofmt \\$:\\:' \
-e 's:^ govet \\$:\\:' \
-e 's:^ govet_shadow \\$:\\:' \
-i "${S}"/test || die
sed -e "s|GO_BUILD_FLAGS=\"[^\"]*\"|GO_BUILD_FLAGS=\"${GO_BUILD_FLAGS}\"|" \
-e "s|go test |go test ${GO_BUILD_FLAGS} |" \
-i ./test || die
}
src_compile() {
./build.sh || die
}
src_test() {
./test || die
}
src_install() {
dobin bin/etcdctl
use doc && dodoc -r Documentation
if use server; then
insinto /etc/${PN}
sed -e 's|^data-dir:|\0 /var/lib/etcd|' -i etcd.conf.yml.sample || die
newins etcd.conf.yml.sample etcd.conf.yml
dobin bin/etcd
dodoc README.md
systemd_newunit "${FILESDIR}/${PN}.service-r1" "${PN}.service"
newtmpfiles "${FILESDIR}/${PN}.tmpfiles.d.conf" ${PN}.conf
newinitd "${FILESDIR}"/${PN}.initd-r1 ${PN}
newconfd "${FILESDIR}"/${PN}.confd-r1 ${PN}
insinto /etc/logrotate.d
newins "${FILESDIR}/${PN}.logrotated" "${PN}"
keepdir /var/lib/${PN} /var/log/${PN}
fowners ${PN}:${PN} /var/lib/${PN} /var/log/${PN}
fperms 0700 /var/lib/${PN}
fperms 0755 /var/log/${PN}
fi
}
pkg_postinst() {
if use server; then
tmpfiles_process ${PN}.conf
fi
}
|
