1 files changed, 47 insertions, 0 deletions
diff --git a/xfce-base/libxfce4util/libxfce4util-4.19.1.ebuild b/xfce-base/libxfce4util/libxfce4util-4.19.1.ebuild
new file mode 100644
index 000000000000..2f1336f79eda
--- /dev/null
+++ b/xfce-base/libxfce4util/libxfce4util-4.19.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit vala
+
+DESCRIPTION="A basic utility library for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/libxfce4util/start
+	https://gitlab.xfce.org/xfce/libxfce4util/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0/7"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
+IUSE="+introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=dev-libs/glib-2.66.0
+	introspection? ( >=dev-libs/gobject-introspection-1.66:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/gtk-doc-am
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable vala)
+	)
+
+	use vala && vala_setup
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}