1 files changed, 45 insertions, 0 deletions
diff --git a/x11-wm/cwm/cwm-6.6.ebuild b/x11-wm/cwm/cwm-6.6.ebuild
new file mode 100644
index 000000000000..083e7d8776c3
--- /dev/null
+++ b/x11-wm/cwm/cwm-6.6.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="OpenBSD fork of calmwm, a clean and lightweight window manager"
+HOMEPAGE="https://www.openbsd.org/cgi-bin/cvsweb/xenocara/app/cwm/
+	https://github.com/chneukirchen/cwm"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/leahneukirchen/${PN}.git"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/leahneukirchen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="ISC"
+SLOT="0"
+
+RDEPEND="x11-libs/libXft
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/bison
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-Makefile.patch"
+)
+
+src_compile() {
+	emake CFLAGS="${CFLAGS} -D_GNU_SOURCE" CC="$(tc-getCC)" PKG_CONFIG="$(tc-getPKG_CONFIG)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr install
+	dodoc README
+	make_session_desktop ${PN} ${PN}
+}