1 files changed, 76 insertions, 0 deletions
diff --git a/x11-misc/albert/albert-0.21.1.ebuild b/x11-misc/albert/albert-0.21.1.ebuild
new file mode 100644
index 000000000000..27f004098044
--- /dev/null
+++ b/x11-misc/albert/albert-0.21.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10,11} )
+
+inherit cmake python-single-r1 xdg-utils
+
+DESCRIPTION="A fast and flexible keyboard launcher"
+HOMEPAGE="https://albertlauncher.github.io/"
+
+PLUGINS_HASH="41bd173e688f8be6d6aab2f8574fab975dcb04b8"
+PYTHON_EXTENSIONS_COMMIT="874af6469607b5cafd45e424d2e27d0efd66231b"
+
+SRC_URI="
+	https://github.com/albertlauncher/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/albertlauncher/plugins/archive/${PLUGINS_HASH}.tar.gz -> ${PN}-plugins-${PLUGINS_HASH}.tar.gz
+	python-extensions? ( https://github.com/albertlauncher/python/archive/${PYTHON_EXTENSIONS_COMMIT}.tar.gz -> ${PN}-python-extensions-${PYTHON_EXTENSIONS_COMMIT}.tar.gz )
+"
+
+LICENSE="all-rights-reserved"	# unclear licensing #766129
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug +python +python-extensions"
+
+REQUIRED_USE="
+	python-extensions? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RDEPEND="
+	app-arch/libarchive:=
+	dev-cpp/muParser
+	dev-libs/qhotkey[qt6]
+	dev-qt/qtbase:6[concurrent,dbus,gui,network,sql,sqlite,widgets]
+	dev-qt/qtscxml:6
+	dev-qt/qtsvg:6
+	sci-libs/libqalculate:=
+	python? (
+		$(python_gen_cond_dep 'dev-python/urllib3[${PYTHON_USEDEP}]')
+		${PYTHON_DEPS}
+	)
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+	python? ( $(python_gen_cond_dep 'dev-python/pybind11[${PYTHON_USEDEP}]') )"
+
+PATCHES=("${FILESDIR}/${PN}-0.20.13-use-system-qhotkey-libraries-and-headers.patch")
+
+src_prepare() {
+	mv "${WORKDIR}"/plugins-${PLUGINS_HASH}/* "${S}"/plugins || die
+	if use python-extensions; then
+		mv "${WORKDIR}"/python-${PYTHON_EXTENSIONS_COMMIT}/* "${S}"/plugins/python/plugins
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DEBUG=$(usex debug)
+		-DBUILD_PYTHON=$(usex python)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}