1 files changed, 49 insertions, 0 deletions
diff --git a/x11-libs/libfm-qt/libfm-qt-0.15.1-r1.ebuild b/x11-libs/libfm-qt/libfm-qt-0.15.1-r1.ebuild
new file mode 100644
index 000000000000..b820cada88ec
--- /dev/null
+++ b/x11-libs/libfm-qt/libfm-qt-0.15.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg-utils
+
+DESCRIPTION="Qt Library for Building File Managers"
+HOMEPAGE="https://lxqt.github.io/"
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="BSD GPL-2+ LGPL-2.1+"
+SLOT="0/7"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	>=dev-util/lxqt-build-tools-0.7.0
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5=
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	>=lxde-base/menu-cache-1.1.0:=
+	media-libs/libexif
+	x11-libs/libxcb
+"
+RDEPEND="${DEPEND}
+	!lxqt-base/lxqt-l10n
+"
+
+PATCHES=( "${FILESDIR}/${PN}-0.15.1-update-runtime-colours.patch" )
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+}