1 files changed, 64 insertions, 0 deletions
diff --git a/www-misc/urlwatch/urlwatch-2.18-r1.ebuild b/www-misc/urlwatch/urlwatch-2.18-r1.ebuild
new file mode 100644
index 000000000000..d8fcfd698a28
--- /dev/null
+++ b/www-misc/urlwatch/urlwatch-2.18-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+# The package uses entry points but setup.py is weird
+# so the eclass doesn't detect it
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="A tool for monitoring webpages for updates"
+HOMEPAGE="https://thp.io/2008/urlwatch/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	dev-python/cssselect[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/minidb[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pycodestyle[${PYTHON_USEDEP}]
+	)
+"
+
+# This will be in the next release
+# https://github.com/thp/urlwatch/commit/44e862282d39a6e23f67c3c0240a93cccbb41a55
+PATCHES=( "${FILESDIR}/${P}-pycodestyle-requirement.patch" )
+
+DOCS=( CHANGELOG.md README.md )
+
+distutils_enable_tests nose
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		if ! has_version dev-python/chump; then
+			elog "Install 'dev-python/chump' to enable Pushover" \
+				"notifications support"
+		fi
+		if ! has_version dev-python/pushbullet-py; then
+			elog "Install 'dev-python/pushbullet-py' to enable" \
+				"Pushbullet notifications support"
+		fi
+		elog "HTML parsing can be improved by installing one of the following packages"
+		elog "and changing the html2text subfilter parameter:"
+		elog "dev-python/beautifulsoup:4"
+		elog "app-text/html2text"
+		elog "dev-python/html2text"
+		elog "www-client/lynx"
+	fi
+}