1 files changed, 50 insertions, 0 deletions
diff --git a/sys-process/acct/acct-6.6.4-r3.ebuild b/sys-process/acct/acct-6.6.4-r3.ebuild
new file mode 100644
index 000000000000..4a561b723628
--- /dev/null
+++ b/sys-process/acct/acct-6.6.4-r3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="GNU system accounting utilities"
+HOMEPAGE="https://savannah.gnu.org/projects/acct/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="sys-apps/texinfo"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.6.4-cross-compile-fixed.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf --enable-linux-multiformat
+}
+
+src_install() {
+	default
+
+	keepdir /var/account
+
+	newinitd "${FILESDIR}"/acct.initd-r2 acct
+	newconfd "${FILESDIR}"/acct.confd-r1 acct
+
+	systemd_dounit "${FILESDIR}"/acct.service
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/acct.logrotate-r1 psacct
+
+	# sys-apps/sysvinit already provides this
+	rm "${ED}"/usr/bin/last "${ED}"/usr/share/man/man1/last.1 || die
+
+	# accton in / is only a temp workaround for #239748
+	dodir /sbin
+	mv "${ED}"/usr/sbin/accton "${ED}"/sbin/ || die
+}