1 files changed, 55 insertions, 0 deletions
diff --git a/sys-fs/lxcfs/lxcfs-4.0.6.ebuild b/sys-fs/lxcfs/lxcfs-4.0.6.ebuild
new file mode 100644
index 000000000000..2ac14261e39b
--- /dev/null
+++ b/sys-fs/lxcfs/lxcfs-4.0.6.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd verify-sig
+
+DESCRIPTION="FUSE filesystem for LXC"
+HOMEPAGE="https://linuxcontainers.org/lxcfs/introduction/ https://github.com/lxc/lxcfs/"
+SRC_URI="https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz
+	verify-sig? ( https://linuxcontainers.org/downloads/lxcfs/${P}.tar.gz.asc )"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64"
+
+RDEPEND="dev-libs/glib:2
+	sys-fs/fuse:3"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-apps/help2man
+	verify-sig? ( app-crypt/openpgp-keys-linuxcontainers )"
+
+RESTRICT="test"
+
+#S="${WORKDIR}/${PN}-${P}"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/linuxcontainers.asc
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Without the localstatedir the filesystem isn't mounted correctly
+	# Without with-distro ./configure will fail when cross-compiling
+	econf --localstatedir=/var --with-distro=gentoo
+}
+
+src_test() {
+	cd tests/ || die
+	emake tests
+	./main.sh || die "Tests failed"
+}
+
+src_install() {
+	default
+
+	newconfd "${FILESDIR}"/lxcfs-4.0.0.confd lxcfs
+	newinitd "${FILESDIR}"/lxcfs-4.0.0.initd lxcfs
+
+	# Provide our own service file (copy of upstream) due to paths being different from upstream,
+	# #728470
+	systemd_newunit "${FILESDIR}"/lxcfs-4.0.0.service lxcfs.service
+}