1 files changed, 72 insertions, 0 deletions
diff --git a/sys-fs/loop-aes/loop-aes-3.8b.ebuild b/sys-fs/loop-aes/loop-aes-3.8b.ebuild
new file mode 100644
index 000000000000..e74a90959434
--- /dev/null
+++ b/sys-fs/loop-aes/loop-aes-3.8b.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-mod-r1
+
+MY_P="${PN/aes/AES}-v${PV}"
+
+DESCRIPTION="Linux kernel module to encrypt disk partitions with AES cipher"
+HOMEPAGE="https://sourceforge.net/projects/loop-aes/"
+SRC_URI="http://loop-aes.sourceforge.net/loop-AES/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~sparc ~x86"
+IUSE="cpu_flags_x86_aes extra-ciphers keyscrub cpu_flags_x86_padlock"
+
+DEPEND="app-crypt/loop-aes-losetup"
+
+PATCHES=( "${FILESDIR}"/loop-aes-3.7w-build-initrd_explicit-losetup.patch )
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	linux-mod-r1_pkg_setup
+
+	CONFIG_CHECK="!BLK_DEV_LOOP"
+}
+
+src_compile() {
+	local modlist=( loop=block::tmp-d-kbuild:all )
+	local modargs=( VAR="${KV_OUT_DIR}"
+		LINUX_SOURCE="${KERNEL_DIR}"
+		KBUILD_OUTPUT="${KBUILD_OUTPUT}"
+		USE_KBUILD=y MODINST=n RUNDM=n )
+
+	if use extra-ciphers; then
+		modlist+=(
+			loop_blowfish=block::tmp-d-kbuild:all
+			loop_serpent=block::tmp-d-kbuild:all
+			loop_twofish=block::tmp-d-kbuild:all )
+		modargs+=( EXTRA_CIPHERS=y )
+	fi
+
+	use cpu_flags_x86_aes && modargs+=( INTELAES=y )
+	use keyscrub && modargs+=( KEYSCRUB=y )
+	use cpu_flags_x86_padlock && modargs+=( PADLOCK=y )
+
+	linux-mod-r1_src_compile
+}
+
+src_install() {
+	linux-mod-r1_src_install
+
+	dodoc README
+	dodoc ChangeLog
+	dobin loop-aes-keygen
+	doman loop-aes-keygen.1
+
+	into /
+	dosbin build-initrd.sh
+}
+
+pkg_postinst() {
+	linux-mod-r1_pkg_postinst
+
+	einfo
+	einfo "For more instructions take a look at examples in README at:"
+	einfo "'${EPREFIX}/usr/share/doc/${PF}'"
+	einfo
+}