1 files changed, 55 insertions, 0 deletions
diff --git a/sys-block/mbuffer/mbuffer-20170921.ebuild b/sys-block/mbuffer/mbuffer-20170921.ebuild
new file mode 100644
index 000000000000..3baf4645d8fa
--- /dev/null
+++ b/sys-block/mbuffer/mbuffer-20170921.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="M(easuring)buffer is a replacement for buffer with additional functionality"
+HOMEPAGE="http://www.maier-komor.de/mbuffer.html"
+SRC_URI="http://www.maier-komor.de/software/mbuffer/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug ssl"
+
+DEPEND="ssl? ( dev-libs/openssl:0= )"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-20170921-resolv-multi-order-issue.patch"
+	"${FILESDIR}/${PN}-20170921-sysconfdir.patch"
+)
+
+src_prepare() {
+	ln -s "${DISTDIR}"/${P}.tgz test.tar #258881
+
+	# Enforce MAKEOPTS=-j1 because src_test() spawns multiple listener
+	# using same port and src_install may have problems (with /etc folder)
+	export MAKEOPTS=-j1
+
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable ssl md5)
+		$(use_enable debug)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	if has usersandbox ${FEATURES} || has network-sandbox ${FEATURES}; then
+		ewarn "Some tests may fail with FEATURES=usersandbox or"
+		ewarn "FEATURES=network-sandbox; Skipping tests because"
+		ewarn "test suite would hang forever in such environments!"
+		return 0;
+	fi
+}
+
+pkg_postinst() {
+	if ! has_version "app-arch/mt-st"; then
+		elog ""
+		elog "If you want autoloader support you need to install \"app-arch/mt-st\" in addition!"
+	fi
+}