1 files changed, 47 insertions, 0 deletions
diff --git a/sys-apps/texinfo/texinfo-6.5-r1.ebuild b/sys-apps/texinfo/texinfo-6.5-r1.ebuild
new file mode 100644
index 000000000000..d42ea554e6d1
--- /dev/null
+++ b/sys-apps/texinfo/texinfo-6.5-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Note: if your package uses the texi2dvi utility, it must depend on the
+# virtual/texi2dvi package to pull in all the right deps.  The tool is not
+# usable out-of-the-box because it requires the large tex packages.
+
+EAPI=6
+
+inherit flag-o-matic
+
+DESCRIPTION="The GNU info program and utilities"
+HOMEPAGE="https://www.gnu.org/software/texinfo/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="nls static"
+
+RDEPEND="
+	!=app-text/tetex-2*
+	>=sys-libs/ncurses-5.2-r2:0=
+	dev-lang/perl:=
+	dev-perl/libintl-perl
+	dev-perl/Unicode-EastAsianWidth
+	dev-perl/Text-Unidecode
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	nls? ( >=sys-devel/gettext-0.19.6 )"
+
+PATCHES=(
+	"${FILESDIR}/${P}"-escape-braces-in-regex.patch
+	"${FILESDIR}/${P}"-perl-5.28-thread-safe-locales.patch
+)
+
+src_configure() {
+	use static && append-ldflags -static
+	local myeconfargs=(
+		--with-external-libintl-perl
+		--with-external-Unicode-EastAsianWidth
+		--with-external-Text-Unidecode
+		$(use_enable nls)
+	)
+	econf "${myeconfargs[@]}"
+}