1 files changed, 70 insertions, 0 deletions
diff --git a/sys-apps/bleachbit/bleachbit-1.19-r1.ebuild b/sys-apps/bleachbit/bleachbit-1.19-r1.ebuild
new file mode 100644
index 000000000000..6e9674128119
--- /dev/null
+++ b/sys-apps/bleachbit/bleachbit-1.19-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="
+	ar ast be bg bn bs ca cs da de el en_AU en_CA en_GB eo es et eu fa fi fo fr
+	gl he hi hr hu hy ia id it ja ko ku ky lt lv ms my nb nds nl nn pl pt pt_BR
+	ro ru se si sk sl sq sr sv ta te th tr ug uk uz vi zh_CN zh_TW"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit distutils-r1 eutils l10n
+
+DESCRIPTION="Clean junk to free disk space and to maintain privacy"
+HOMEPAGE="https://www.bleachbit.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gtk nls"
+
+RDEPEND="gtk? ( dev-python/pygtk:2[$PYTHON_USEDEP] )"
+
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+python_prepare_all() {
+	rem_locale() {
+		rm "po/${1}.po" &>/dev/null
+		if [[ $? -ne 0 ]]; then
+			eerror "Removing of ${1}.po failed"
+			die
+		fi
+	}
+
+	l10n_find_plocales_changes po "" ".po"
+	l10n_for_each_disabled_locale_do rem_locale
+
+	# choose correct Python implementation, bug #465254
+	sed -i 's/python/$(PYTHON)/g' po/Makefile || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use nls && emake -C po
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use nls && emake -C po DESTDIR="${D}" install
+
+	# https://bugs.gentoo.org/388999
+	insinto /usr/share/${PN}/cleaners
+	doins cleaners/*.xml
+
+	newbin ${PN}.py ${PN}
+	python_replicate_script "${D}/usr/bin/${PN}"
+
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+}
+
+pkg_postinst() {
+	elog "Bleachbit has optional notification support. To enable, please install:"
+	elog ""
+	elog "  dev-python/notify-python"
+}