1 files changed, 57 insertions, 0 deletions
diff --git a/sys-apps/bfs/bfs-3.2.ebuild b/sys-apps/bfs/bfs-3.2.ebuild
new file mode 100644
index 000000000000..c99fcb8e9ad7
--- /dev/null
+++ b/sys-apps/bfs/bfs-3.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edo flag-o-matic toolchain-funcs
+
+DESCRIPTION="Breadth-first version of the UNIX find command"
+HOMEPAGE="https://tavianator.com/projects/bfs.html"
+SRC_URI="https://github.com/tavianator/bfs/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="0BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc"
+IUSE="acl caps debug io-uring selinux unicode"
+
+DEPEND="
+	acl? ( virtual/acl )
+	caps? ( sys-libs/libcap )
+	io-uring? ( sys-libs/liburing:= )
+	selinux? ( sys-libs/libselinux )
+	unicode? ( dev-libs/oniguruma:= )
+"
+RDEPEND="${DEPEND}"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	# Not available on Linux
+	acl_is_trivial_np acl_trivial fdclosedir getdents getprogname
+	posix_spawn_file_actions_addfchdir
+)
+
+src_configure() {
+	tc-export CC PKG_CONFIG
+	use debug || append-cppflags -DNDEBUG
+
+	edo ./configure \
+		$(use_enable acl libacl) \
+		$(use_enable caps libcap) \
+		$(use_enable selinux libselinux) \
+		$(use_enable io-uring liburing) \
+		$(use_enable unicode oniguruma) \
+		V=1
+}
+
+src_compile() {
+	emake V=1
+}
+
+src_test() {
+	# -n check gets confused so need manual src_test definition?
+	emake V=1 check
+}
+
+src_install() {
+	emake V=1 DESTDIR="${D}" install
+	einstalldocs
+}