1 files changed, 40 insertions, 0 deletions
diff --git a/sci-physics/qmeq/qmeq-1.0.ebuild b/sci-physics/qmeq/qmeq-1.0.ebuild
new file mode 100644
index 000000000000..b08ced5452ae
--- /dev/null
+++ b/sci-physics/qmeq/qmeq-1.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Quantum master equation package for Quantum dot transport calculations"
+HOMEPAGE="https://github.com/gedaskir/qmeq"
+SRC_URI="
+	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	examples? ( https://github.com/gedaskir/${PN}-examples/archive/${PV}.tar.gz -> ${PN}-examples-${PV}.tgz )
+"
+
+KEYWORDS="~amd64"
+IUSE="examples"
+LICENSE="BSD-2"
+SLOT="0"
+
+COMMON_DEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	examples? ( dev-python/jupyter[${PYTHON_USEDEP}] )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+src_install() {
+	distutils-r1_src_install
+	docompress -x "/usr/share/doc/${PF}"
+	use examples && dodoc -r "${WORKDIR}/${PN}-examples-${PV}"/*
+}