1 files changed, 46 insertions, 0 deletions
diff --git a/sci-libs/spr/spr-3.3.2-r2.ebuild b/sci-libs/spr/spr-3.3.2-r2.ebuild
new file mode 100644
index 000000000000..230353e35cc6
--- /dev/null
+++ b/sci-libs/spr/spr-3.3.2-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Statistical analysis and machine learning library"
+HOMEPAGE="https://statpatrec.sourceforge.net/"
+SRC_URI="mirror://sourceforge/statpatrec/${P^^}.tar.gz"
+S="${WORKDIR}/${P^^}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="root static-libs"
+
+DEPEND="root? ( sci-physics/root )"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-autotools.patch
+	"${FILESDIR}"/${P}-gcc46.patch
+	"${FILESDIR}"/${P}-fix-c++14.patch
+)
+
+src_prepare() {
+	default
+	rm aclocal.m4 || die
+	eautoreconf
+	cp data/gauss* src/ || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with root)
+}
+
+src_install() {
+	default
+	if ! use static-libs; then
+		find "${ED}" -name '*.la' -delete || die
+	fi
+}