1 files changed, 67 insertions, 0 deletions
diff --git a/sci-chemistry/gabedit/gabedit-2.4.7.ebuild b/sci-chemistry/gabedit/gabedit-2.4.7.ebuild
new file mode 100644
index 000000000000..755e1928327a
--- /dev/null
+++ b/sci-chemistry/gabedit/gabedit-2.4.7.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit eutils toolchain-funcs versionator
+
+MY_PN=${PN/g/G}
+MY_PV=$(delete_all_version_separators)
+MY_P="${MY_PN}Src${MY_PV}"
+
+DESCRIPTION="GUI for computational chemistry packages"
+HOMEPAGE="http://gabedit.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="openmp"
+
+RDEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:2
+	x11-libs/gtkglext
+	x11-libs/gl2ps
+	x11-libs/pango
+	virtual/opengl
+	virtual/glu"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	sed -i "/rmdir tmp/d" "${S}"/Makefile || die
+	sed \
+		-e "/GTK_DISABLE_DEPRECATED/s:define:undef:g" \
+		-i "${S}/Config.h" || die
+	sed -e 's:-g::g' -i Makefile || die
+	cp "${FILESDIR}"/CONFIG.Gentoo "${S}"/CONFIG
+
+	if use openmp && tc-has-openmp; then
+		cat <<- EOF >> "${S}/CONFIG"
+			OMPLIB=-fopenmp
+			OMPCFLAGS=-DENABLE_OMP -fopenmp
+		EOF
+	fi
+	echo "COMMONCFLAGS = ${CFLAGS} -DENABLE_DEPRECATED \$(OMPCFLAGS) \$(DRAWGEOMGL)" >> CONFIG
+
+	tc-export CC
+}
+
+src_compile() {
+	emake clean
+	emake external_gl2ps=1
+}
+
+src_install() {
+	local size
+	dobin ${PN}
+	dodoc ChangeLog
+	for size in 16 24 32 48; do
+		doicon -s ${size} icons/Gabedit${size}.*
+	done
+}