8 files changed, 400 insertions, 213 deletions
diff --git a/net-misc/Manifest.gz b/net-misc/Manifest.gz
index 1073ef3de021..8cd7bf1043b1 100644
--- a/net-misc/Manifest.gz
+++ b/net-misc/Manifest.gz
diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index 217d7d68ac6a..7c3e27a1e56a 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,12 +1,10 @@
 AUX nextcloud-client-3.6.6-no-redefine-fortify-source.patch 1447 BLAKE2B 14a3a1a1206a0a0027aa9c59e07b6d81174428aaaf90fba5706e9c7a2f076753a4b2f364ffa0f22dabf785d58832dde1aeba61e3cb3cc92feffa8b4b614c5d65 SHA512 808c10f8ea1905d54f62f895b2089c2acb602e838143f6a4268a5ab1e966ffe6ff01f132b8b65e0eebde21435a859cc7fb4f868a2ca81da4dcaa02292a337ed7
 DIST nextcloud-client-3.10.0.tar.gz 13529232 BLAKE2B 3c3f2e823df35d365ae73afa4d59e9afd44bac5873de336b340712c03a18b38bf33f1af8b9dec52f8628034feeb720a3e48e6d435f64f170a57c17f2bfca7d56 SHA512 f4cfa4884e445cf30b4b47077ba4db31f70f1388e235d994886e6aa9e4b0a80426159336d476d057abf422d4201ea608cf54f4e9b04189198f48214315a67330
 DIST nextcloud-client-3.10.1.tar.gz 13519993 BLAKE2B a23afcfe35c3f7a8a01656cf67ea681a7eac40989939b5bf1991eb7334993fddab6c501636292b8526c02b872af8cfed97568e2d263a3dbf3f78985caac3a1ce SHA512 866fcae59a6afc39bd874892f1ca6fc2afcfa2e0166d431829462afbf8d6f7b25a46700737515fe98c3a002c3a34bd9de42cbecdf80134661544c1e590708b43
-DIST nextcloud-client-3.8.2.tar.gz 15605319 BLAKE2B babd45d0a38d5206afd9c2b69e7ea580aeb90df2606932cbfc28f688b20bb026e566ca8a30112975ae38c8d9807339433c8b972230c6a8122cb93ffadd2eecab SHA512 231e074fd3dcc8f69d62616ff4aeec5e748891bf93fc783861008a4e04a12066e77e1449d94f599e5edfa9861bad684403aef80e909e095c16170d8607626a9d
-DIST nextcloud-client-3.9.1.tar.gz 15733029 BLAKE2B e7e792b2ea7985c02627661b4686bf568dfe8cfe722babbf5507293daec57b754566d259d3fd4bc0b224e1dc34ae0afa4c757e75910c4d6d4ded692f0d7c2b02 SHA512 b3c77243efed3b70a59c157ae6f45ebf8eb8c4926e23bd78b364e93cbc2612ec220db60ef6bd55e288a2eb5a454fea87fd348116057b052a15b5c6c69f0654d2
+DIST nextcloud-client-3.11.0.tar.gz 13595770 BLAKE2B 25d882d4f8c85e66a6db3d00214d0faec8b3024f1d264d37200ecc9cf1f93876e36f383b7617f767d5bd6f0ba53b16d46bb9bb3fd63c4553a43e3fdade5cc679 SHA512 42e18b1f68024f8f792de2720be144e20ffe2e6bc8086721e92832c006d897b59f3c480d39b5d411ded50770ab6b0bfbbb6106aae889eb92be2e9eb345121082
 DIST nextcloud-client-3.9.4.tar.gz 15768508 BLAKE2B 7c06434538e9e95bed284ba07692d0d4d594639a145c2f3b67b8e81586fb98e1592eca54b9ee3cc638f8226ebb83e89e60a79238c76696fe9ca033209646eb13 SHA512 9f99278deb024ce105bae14d8dadc626b835486858e94f5483e9da3d06340a29e0941648cccfc30714c15ce25a6b77c4aa05a17fc213d7aa84803ffc13dca5a4
 EBUILD nextcloud-client-3.10.0.ebuild 2719 BLAKE2B 08d1ee57eea57daf8c2786911d189b9840b5cd732e744b6840bebc157167f0c5d89af5c24aedf7995863580c7b0aa0a00730d2b598c9983d0d1e41a8cdec508d SHA512 595258969684088b6b304bfdadbe80a3aa6b5a9dfed7d1062c1fb5f0f1b6deb59050cdedf11c62697c91fdcf3cf72ef1a19127fa2d01862fd9bdb6a868e3a8ce
 EBUILD nextcloud-client-3.10.1.ebuild 2719 BLAKE2B 08d1ee57eea57daf8c2786911d189b9840b5cd732e744b6840bebc157167f0c5d89af5c24aedf7995863580c7b0aa0a00730d2b598c9983d0d1e41a8cdec508d SHA512 595258969684088b6b304bfdadbe80a3aa6b5a9dfed7d1062c1fb5f0f1b6deb59050cdedf11c62697c91fdcf3cf72ef1a19127fa2d01862fd9bdb6a868e3a8ce
-EBUILD nextcloud-client-3.8.2-r1.ebuild 2717 BLAKE2B 637408938ba4ae238a40ae275860ee1db8e4f036d921cd7eac6c20500dd78ab86f3aa2c98fa12edf402f14550755bd993a0e55adb0dc99f1cb1da1952dcb3d3c SHA512 57d91d98de4ff61ba6f5c32a8e122c290ace8c135bfccadb0279b78580f9d05870a59580edf1fa774728132f8653e1ef5a098fa090f2f19cadb50ac916c4a047
-EBUILD nextcloud-client-3.9.1.ebuild 2717 BLAKE2B 637408938ba4ae238a40ae275860ee1db8e4f036d921cd7eac6c20500dd78ab86f3aa2c98fa12edf402f14550755bd993a0e55adb0dc99f1cb1da1952dcb3d3c SHA512 57d91d98de4ff61ba6f5c32a8e122c290ace8c135bfccadb0279b78580f9d05870a59580edf1fa774728132f8653e1ef5a098fa090f2f19cadb50ac916c4a047
+EBUILD nextcloud-client-3.11.0.ebuild 2719 BLAKE2B 08d1ee57eea57daf8c2786911d189b9840b5cd732e744b6840bebc157167f0c5d89af5c24aedf7995863580c7b0aa0a00730d2b598c9983d0d1e41a8cdec508d SHA512 595258969684088b6b304bfdadbe80a3aa6b5a9dfed7d1062c1fb5f0f1b6deb59050cdedf11c62697c91fdcf3cf72ef1a19127fa2d01862fd9bdb6a868e3a8ce
 EBUILD nextcloud-client-3.9.4.ebuild 2717 BLAKE2B 637408938ba4ae238a40ae275860ee1db8e4f036d921cd7eac6c20500dd78ab86f3aa2c98fa12edf402f14550755bd993a0e55adb0dc99f1cb1da1952dcb3d3c SHA512 57d91d98de4ff61ba6f5c32a8e122c290ace8c135bfccadb0279b78580f9d05870a59580edf1fa774728132f8653e1ef5a098fa090f2f19cadb50ac916c4a047
 MISC metadata.xml 712 BLAKE2B 423b16fa8879b0bc21d8ff1c692e5e592f571b5d69dcdd35fe79dae08b770c0d5beb2cbf71af2e7410d1dfd6917d15bac0482a84a40ce602ab03ab0f59940355 SHA512 2cfeff27549192c2aaa9c64369545e75b3a056c123d7647c96505dd410490230027401961e95ef88c93b0485393bd54aa11ddc922bcaf2782f9e68a2d8d17b32
diff --git a/net-misc/nextcloud-client/nextcloud-client-3.8.2-r1.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.11.0.ebuild
index 23b5a83aabf2..94cff32e49fb 100644
--- a/net-misc/nextcloud-client/nextcloud-client-3.8.2-r1.ebuild
+++ b/net-misc/nextcloud-client/nextcloud-client-3.11.0.ebuild
@@ -14,7 +14,7 @@ S="${WORKDIR}/desktop-${PV/_/-}"
 
 LICENSE="CC-BY-3.0 GPL-2"
 SLOT="0"
-KEYWORDS="amd64 arm64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~x86"
 IUSE="doc dolphin nautilus test webengine"
 RESTRICT="!test? ( test )"
 
diff --git a/net-misc/nextcloud-client/nextcloud-client-3.9.1.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.9.1.ebuild
deleted file mode 100644
index 23b5a83aabf2..000000000000
--- a/net-misc/nextcloud-client/nextcloud-client-3.9.1.ebuild
+++ /dev/null
@@ -1,115 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake virtualx xdg
-
-DESCRIPTION="Desktop Syncing Client for Nextcloud"
-HOMEPAGE="https://github.com/nextcloud/desktop"
-SRC_URI="
-	https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz
-"
-S="${WORKDIR}/desktop-${PV/_/-}"
-
-LICENSE="CC-BY-3.0 GPL-2"
-SLOT="0"
-KEYWORDS="amd64 arm64 ~x86"
-IUSE="doc dolphin nautilus test webengine"
-RESTRICT="!test? ( test )"
-
-# slot op for qtqui as this package uses private API parts of qtqui
-# src/gui/generalsettings.cpp:#include <private/qzipwriter_p.h>
-RDEPEND="
-	>=dev-db/sqlite-3.34:3
-	>=dev-libs/openssl-1.1.0:0=
-	dev-libs/qtkeychain:=[qt5(+)]
-	dev-qt/qtcore:5
-	dev-qt/qtdbus:5
-	dev-qt/qtdeclarative:5
-	dev-qt/qtgui:5=
-	dev-qt/qtnetwork:5[ssl]
-	dev-qt/qtquickcontrols2:5
-	dev-qt/qtsvg:5
-	dev-qt/qtwebsockets:5
-	dev-qt/qtwidgets:5
-	net-libs/libcloudproviders
-	kde-frameworks/karchive:5
-	sys-libs/zlib
-	dolphin? (
-		kde-frameworks/kcoreaddons:5
-		kde-frameworks/kio:5
-	)
-	nautilus? ( dev-python/nautilus-python )
-	webengine? ( dev-qt/qtwebengine:5[widgets] )
-"
-DEPEND="
-	${RDEPEND}
-	dev-qt/qtconcurrent:5
-	dev-qt/qtxml:5
-	|| ( gnome-base/librsvg media-gfx/inkscape )
-	doc? (
-		dev-python/sphinx
-		dev-tex/latexmk
-		dev-texlive/texlive-latexextra
-		virtual/latex-base
-	)
-	test? (
-		dev-qt/qttest:5
-		dev-util/cmocka
-	)
-"
-BDEPEND="
-	dev-qt/linguist-tools:5
-	dolphin? ( kde-frameworks/extra-cmake-modules )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-3.6.6-no-redefine-fortify-source.patch
-)
-
-src_prepare() {
-	# Keep tests in ${T}
-	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
-		-DBUILD_UPDATER=OFF
-		$(cmake_use_find_package doc Sphinx)
-		$(cmake_use_find_package doc PdfLatex)
-		$(cmake_use_find_package webengine Qt5WebEngine)
-		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
-		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
-		-DBUILD_SHELL_INTEGRATION_NAUTILUS=$(usex nautilus)
-		-DBUILD_TESTING=$(usex test)
-	)
-
-	cmake_src_configure
-}
-
-src_test() {
-	virtx cmake_src_test
-}
-
-src_compile() {
-	local compile_targets=(all)
-	if use doc; then
-		compile_targets+=(doc doc-man)
-	fi
-	cmake_src_compile ${compile_targets[@]}
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if ! has_version -r "dev-libs/qtkeychain[keyring]"; then
-		elog "dev-libs/qtkeychain has not been build with the 'keyring' USE flag."
-		elog "Please consider enabling the 'keyring' USE flag. Otherwise you may"
-		elog "have to authenticate manually every time you start the nextlcoud client."
-		elog "See https://bugs.gentoo.org/912844 for more information."
-	fi
-}
diff --git a/net-misc/openssh/Manifest b/net-misc/openssh/Manifest
index bb2f8963ac5b..6a37030f342a 100644
--- a/net-misc/openssh/Manifest
+++ b/net-misc/openssh/Manifest
@@ -26,5 +26,6 @@ EBUILD openssh-9.3_p1-r1.ebuild 13447 BLAKE2B 4e5798dfb8bcae6554dbf9ebad887a7527
 EBUILD openssh-9.3_p2.ebuild 13571 BLAKE2B c271bdc5b85ebb0f8669f5cd838fba860960fb4af8b2e820d7a92cd3e91a862eee44534ab42f3f7177acb3e868d3278418525d441d5eb22ddf4b61ff820b2678 SHA512 8651efe3d7e0d5aaae6b11bccb0fccd6338a938a57a5aa860203cf3af84520f32c0cf2fb563f02e50e71c696b86a712be3f6db335802ada660b82a508bd56c9c
 EBUILD openssh-9.4_p1-r1.ebuild 13388 BLAKE2B e9e6c2bdc30df9c16488c0b1d176e2e3ad84b6d26b6061ad1dfcc4ac968b1b0e0aef70ee8e83ea31d7165d5ab9f2223ce6bbccf8484b9a80a3e5ec76377ce624 SHA512 bab7dd22e43ce950c65365104d132297deb66d577a7f58a1d4bac67ea7e9b2319cdcab7ecf739f316528229bf21b5a0ec2b9ed7f690078be4ccefce0663ae596
 EBUILD openssh-9.5_p1-r2.ebuild 13263 BLAKE2B 2c7d439af69c61716023dfbc9ea77b162101c4e3bd039030aafca0fbec2a1788b1bf7756d739e23dad5bfa7fe6b354c4689536d9b583c4c017618530cb040b63 SHA512 e02c9245bb86e378f354c1bcf88765696beb34a0af79a23256a0a9c4f4af8e9f8f8240bf78a0072b409097ebb3395b799812d58ac3f2957b878cd709a6aa4e66
+EBUILD openssh-9.6_p1-r1.ebuild 14020 BLAKE2B f275aa7b7588bfdae576317f6d7aa506083b699fe48b51f0b6b3a10c6c912bd5862edaef2d698c58f19831585e7dc82de2ce6c0410c2a6282740f3474317029b SHA512 858b73e93046b494f8627c500a3dc2bc38eb31bba664c073f9291f5d9c070d4bd49443b0b0aedac92b289da566b82a7da236513ddf508080ec0f48e7f9423833
 EBUILD openssh-9.6_p1.ebuild 13219 BLAKE2B 1518912a47a93f51d3e5091d74f2605144749b6d364f276a4091761d7712daaeb77da18e46d2985d37edf838a6b089fe5c10714c5c1344f4a0b5677ba86eb05b SHA512 5bbb566bdcade2760b48508b99768fcc26e082eecc2aa2c0d4d4b4eb01cfc056e17c48fd51e772b1d8c30e872007755e14434a55d7cefec273f629630a35bd9e
 MISC metadata.xml 1788 BLAKE2B d04d3030f70f3615522672fa56e684acaa67ddce8d16cce86ba8911fb8fc11ed152be012ecf560427d271868c4841a7422aaa644305947302d3ebab62bdb577d SHA512 bd328e3a33ce04b989149333db5f774f1b52540f12ef83b08b7fcf136ae2a3a9c83bef42c28991d3536249098ca0b9ffd21e583d93599580510d8619e9fd01ca
diff --git a/net-misc/openssh/openssh-9.6_p1-r1.ebuild b/net-misc/openssh/openssh-9.6_p1-r1.ebuild
new file mode 100644
index 000000000000..84130f1d6514
--- /dev/null
+++ b/net-misc/openssh/openssh-9.6_p1-r1.ebuild
@@ -0,0 +1,396 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/openssh.org.asc
+inherit user-info flag-o-matic autotools pam systemd toolchain-funcs verify-sig
+
+# Make it more portable between straight releases
+# and _p? releases.
+PARCH=${P/_}
+
+DESCRIPTION="Port of OpenBSD's free SSH release"
+HOMEPAGE="https://www.openssh.com/"
+SRC_URI="
+	mirror://openbsd/OpenSSH/portable/${PARCH}.tar.gz
+	verify-sig? ( mirror://openbsd/OpenSSH/portable/${PARCH}.tar.gz.asc )
+"
+S="${WORKDIR}/${PARCH}"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+# Probably want to drop ssl defaulting to on in a future version.
+IUSE="abi_mips_n32 audit debug kerberos ldns libedit livecd pam +pie security-key selinux +ssl static test X xmss"
+
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	ldns? ( ssl )
+	pie? ( !static )
+	static? ( !kerberos !pam )
+	xmss? ( ssl  )
+	test? ( ssl )
+"
+
+# tests currently fail with XMSS
+REQUIRED_USE+="test? ( !xmss )"
+
+LIB_DEPEND="
+	audit? ( sys-process/audit[static-libs(+)] )
+	ldns? (
+		net-libs/ldns[static-libs(+)]
+		net-libs/ldns[ecdsa(+),ssl(+)]
+	)
+	libedit? ( dev-libs/libedit:=[static-libs(+)] )
+	security-key? ( >=dev-libs/libfido2-1.5.0:=[static-libs(+)] )
+	selinux? ( >=sys-libs/libselinux-1.28[static-libs(+)] )
+	ssl? ( >=dev-libs/openssl-1.1.1l-r1:0=[static-libs(+)] )
+	virtual/libcrypt:=[static-libs(+)]
+	>=sys-libs/zlib-1.2.3:=[static-libs(+)]
+"
+RDEPEND="
+	acct-group/sshd
+	acct-user/sshd
+	!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
+	pam? ( sys-libs/pam )
+	kerberos? ( virtual/krb5 )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/os-headers
+	kernel_linux? ( !prefix-guest? ( >=sys-kernel/linux-headers-5.1 ) )
+	static? ( ${LIB_DEPEND} )
+"
+RDEPEND="
+	${RDEPEND}
+	!net-misc/openssh-contrib
+	pam? ( >=sys-auth/pambase-20081028 )
+	!prefix? ( sys-apps/shadow )
+	X? ( x11-apps/xauth )
+"
+# Weird dep construct for newer gcc-config for bug #872416
+BDEPEND="
+	sys-devel/autoconf
+	virtual/pkgconfig
+	|| (
+		>=sys-devel/gcc-config-2.6
+		>=sys-devel/clang-toolchain-symlinks-14-r1:14
+		>=sys-devel/clang-toolchain-symlinks-15-r1:15
+		>=sys-devel/clang-toolchain-symlinks-16-r1:*
+	)
+	verify-sig? ( sec-keys/openpgp-keys-openssh )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-9.3_p1-disable-conch-interop-tests.patch"
+	"${FILESDIR}/${PN}-9.3_p1-fix-putty-tests.patch"
+	"${FILESDIR}/${PN}-9.3_p1-deny-shmget-shmat-shmdt-in-preauth-privsep-child.patch"
+)
+
+pkg_pretend() {
+	local i enabled_eol_flags disabled_eol_flags
+	for i in hpn sctp X509; do
+		if has_version "net-misc/openssh[${i}]"; then
+			enabled_eol_flags+="${i},"
+			disabled_eol_flags+="-${i},"
+		fi
+	done
+
+	if [[ -n ${enabled_eol_flags} && ${OPENSSH_EOL_USE_FLAGS_I_KNOW_WHAT_I_AM_DOING} != yes ]]; then
+		# Skip for binary packages entirely because of environment saving, bug #907892
+		[[ ${MERGE_TYPE} == binary ]] && return
+
+		ewarn "net-misc/openssh does not support USE='${enabled_eol_flags%,}' anymore."
+		ewarn "The Base system team *STRONGLY* recommends you not rely on this functionality,"
+		ewarn "since these USE flags required third-party patches that often trigger bugs"
+		ewarn "and are of questionable provenance."
+		ewarn
+		ewarn "If you must continue relying on this functionality, switch to"
+		ewarn "net-misc/openssh-contrib. You will have to remove net-misc/openssh from your"
+		ewarn "world file first: 'emerge --deselect net-misc/openssh'"
+		ewarn
+		ewarn "In order to prevent loss of SSH remote login access, we will abort the build."
+		ewarn "Whether you proceed with disabling the USE flags or switch to the -contrib"
+		ewarn "variant, when re-emerging you will have to set"
+		ewarn
+		ewarn "  OPENSSH_EOL_USE_FLAGS_I_KNOW_WHAT_I_AM_DOING=yes"
+
+		die "Building net-misc/openssh[${disabled_eol_flags%,}] without OPENSSH_EOL_USE_FLAGS_I_KNOW_WHAT_I_AM_DOING=yes"
+	fi
+
+	# Make sure people who are using tcp wrappers are notified of its removal. #531156
+	if grep -qs '^ *sshd *:' "${EROOT}"/etc/hosts.{allow,deny} ; then
+		ewarn "Sorry, but openssh no longer supports tcp-wrappers, and it seems like"
+		ewarn "you're trying to use it.  Update your ${EROOT}/etc/hosts.{allow,deny} please."
+	fi
+}
+
+src_prepare() {
+	sed -i \
+		-e "/_PATH_XAUTH/s:/usr/X11R6/bin/xauth:${EPREFIX}/usr/bin/xauth:" \
+		pathnames.h || die
+
+	# don't break .ssh/authorized_keys2 for fun
+	sed -i '/^AuthorizedKeysFile/s:^:#:' sshd_config || die
+
+	[[ -d ${WORKDIR}/patches ]] && PATCHES+=( "${WORKDIR}"/patches )
+
+	default
+
+	# These tests are currently incompatible with PORTAGE_TMPDIR/sandbox
+	sed -e '/\t\tpercent \\/ d' \
+		-i regress/Makefile || die
+
+	tc-export PKG_CONFIG
+	local sed_args=(
+		-e "s:-lcrypto:$(${PKG_CONFIG} --libs openssl):"
+		# Disable fortify flags ... our gcc does this for us
+		-e 's:-D_FORTIFY_SOURCE=2::'
+	)
+
+	# _XOPEN_SOURCE causes header conflicts on Solaris
+	[[ ${CHOST} == *-solaris* ]] && sed_args+=(
+		-e 's/-D_XOPEN_SOURCE//'
+	)
+	sed -i "${sed_args[@]}" configure{.ac,} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	addwrite /dev/ptmx
+
+	use debug && append-cppflags -DSANDBOX_SECCOMP_FILTER_DEBUG
+	use static && append-ldflags -static
+	use xmss && append-cflags -DWITH_XMSS
+
+	if [[ ${CHOST} == *-solaris* ]] ; then
+		# Solaris' glob.h doesn't have things like GLOB_TILDE, configure
+		# doesn't check for this, so force the replacement to be put in
+		# place
+		append-cppflags -DBROKEN_GLOB
+	fi
+
+	# use replacement, RPF_ECHO_ON doesn't exist here
+	[[ ${CHOST} == *-darwin* ]] && export ac_cv_func_readpassphrase=no
+
+	local myconf=(
+		--with-ldflags="${LDFLAGS}"
+		--disable-strip
+		--with-pid-dir="${EPREFIX}"$(usex kernel_linux '' '/var')/run
+		--sysconfdir="${EPREFIX}"/etc/ssh
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir)/misc
+		--datadir="${EPREFIX}"/usr/share/openssh
+		--with-privsep-path="${EPREFIX}"/var/empty
+		--with-privsep-user=sshd
+
+		# --with-hardening adds the following in addition to flags we
+		# already set in our toolchain:
+		# * -ftrapv (which is broken with GCC anyway),
+		# * -ftrivial-auto-var-init=zero (which is nice, but not the end of
+		#    the world to not have)
+		# * -fzero-call-used-regs=used (history of miscompilations with
+		#    Clang (bug #872548), ICEs on m68k (bug #920350, gcc PR113086,
+		#    gcc PR104820, gcc PR104817, gcc PR110934)).
+		#
+		# Furthermore, OSSH_CHECK_CFLAG_COMPILE does not use AC_CACHE_CHECK,
+		# so we cannot just disable -fzero-call-used-regs=used.
+		#
+		# Therefore, just pass --without-hardening, given it doesn't negate
+		# our already hardened toolchain defaults, and avoids adding flags
+		# which are known-broken in both Clang and GCC and haven't been
+		# proven reliable.
+		--without-hardening
+
+		$(use_with audit audit linux)
+		$(use_with kerberos kerberos5 "${EPREFIX}"/usr)
+		$(use_with ldns)
+		$(use_with libedit)
+		$(use_with pam)
+		$(use_with pie)
+		$(use_with selinux)
+		$(use_with security-key security-key-builtin)
+		$(use_with ssl openssl)
+		$(use_with ssl ssl-engine)
+	)
+
+	if use elibc_musl; then
+		# musl defines bogus values for UTMP_FILE and WTMP_FILE (bug #753230)
+		myconf+=( --disable-utmp --disable-wtmp )
+	fi
+
+	# Workaround for Clang 15 miscompilation with -fzero-call-used-regs=all
+	# bug #869839 (https://github.com/llvm/llvm-project/issues/57692)
+	tc-is-clang && myconf+=( --without-hardening )
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	local tests=( compat-tests )
+	local shell=$(egetshell "${UID}")
+	if [[ ${shell} == */nologin ]] || [[ ${shell} == */false ]] ; then
+		ewarn "Running the full OpenSSH testsuite requires a usable shell for the 'portage'"
+		ewarn "user, so we will run a subset only."
+		tests+=( interop-tests )
+	else
+		tests+=( tests )
+	fi
+
+	local -x SUDO= SSH_SK_PROVIDER= TEST_SSH_UNSAFE_PERMISSIONS=1
+	mkdir -p "${HOME}"/.ssh || die
+	emake -j1 "${tests[@]}" </dev/null
+}
+
+# Gentoo tweaks to default config files.
+tweak_ssh_configs() {
+	local locale_vars=(
+		# These are language variables that POSIX defines.
+		# http://pubs.opengroup.org/onlinepubs/9699919799/basedefs/V1_chap08.html#tag_08_02
+		LANG LC_ALL LC_COLLATE LC_CTYPE LC_MESSAGES LC_MONETARY LC_NUMERIC LC_TIME
+
+		# These are the GNU extensions.
+		# https://www.gnu.org/software/autoconf/manual/html_node/Special-Shell-Variables.html
+		LANGUAGE LC_ADDRESS LC_IDENTIFICATION LC_MEASUREMENT LC_NAME LC_PAPER LC_TELEPHONE
+	)
+
+	dodir /etc/ssh/ssh_config.d /etc/ssh/sshd_config.d
+	cat <<-EOF >> "${ED}"/etc/ssh/ssh_config || die
+	Include "${EPREFIX}/etc/ssh/ssh_config.d/*.conf"
+	EOF
+	cat <<-EOF >> "${ED}"/etc/ssh/sshd_config || die
+	Include "${EPREFIX}/etc/ssh/sshd_config.d/*.conf"
+	EOF
+
+	cat <<-EOF >> "${ED}"/etc/ssh/ssh_config.d/9999999gentoo.conf || die
+	# Send locale environment variables (bug #367017)
+	SendEnv ${locale_vars[*]}
+
+	# Send COLORTERM to match TERM (bug #658540)
+	SendEnv COLORTERM
+	EOF
+
+	cat <<-EOF >> "${ED}"/etc/ssh/ssh_config.d/9999999gentoo-security.conf || die
+	RevokedHostKeys "${EPREFIX}/etc/ssh/ssh_revoked_hosts"
+	EOF
+
+	cat <<-EOF >> "${ED}"/etc/ssh/ssh_revoked_hosts || die
+	# https://github.blog/2023-03-23-we-updated-our-rsa-ssh-host-key/
+	ssh-rsa AAAAB3NzaC1yc2EAAAABIwAAAQEAq2A7hRGmdnm9tUDbO9IDSwBK6TbQa+PXYPCPy6rbTrTtw7PHkccKrpp0yVhp5HdEIcKr6pLlVDBfOLX9QUsyCOV0wzfjIJNlGEYsdlLJizHhbn2mUjvSAHQqZETYP81eFzLQNnPHt4EVVUh7VfDESU84KezmD5QlWpXLmvU31/yMf+Se8xhHTvKSCZIFImWwoG6mbUoWf9nzpIoaSjB+weqqUUmpaaasXVal72J+UX2B+2RPW3RcT0eOzQgqlJL3RKrTJvdsjE3JEAvGq3lGHSZXy28G3skua2SmVi/w4yCE6gbODqnTWlg7+wC604ydGXA8VJiS5ap43JXiUFFAaQ==
+	EOF
+
+	cat <<-EOF >> "${ED}"/etc/ssh/sshd_config.d/9999999gentoo.conf || die
+	# Allow client to pass locale environment variables (bug #367017)
+	AcceptEnv ${locale_vars[*]}
+
+	# Allow client to pass COLORTERM to match TERM (bug #658540)
+	AcceptEnv COLORTERM
+	EOF
+
+	if use pam ; then
+		cat <<-EOF >> "${ED}"/etc/ssh/sshd_config.d/9999999gentoo-pam.conf || die
+		UsePAM yes
+		# This interferes with PAM.
+		PasswordAuthentication no
+		# PAM can do its own handling of MOTD.
+		PrintMotd no
+		PrintLastLog no
+		EOF
+	fi
+
+	if use livecd ; then
+		cat <<-EOF >> "${ED}"/etc/ssh/sshd_config.d/9999999gentoo-livecd.conf || die
+		# Allow root login with password on livecds.
+		PermitRootLogin Yes
+		EOF
+	fi
+}
+
+src_install() {
+	emake install-nokeys DESTDIR="${D}"
+	fperms 600 /etc/ssh/sshd_config
+	dobin contrib/ssh-copy-id
+	newinitd "${FILESDIR}"/sshd-r1.initd sshd
+	newconfd "${FILESDIR}"/sshd-r1.confd sshd
+
+	if use pam; then
+		newpamd "${FILESDIR}"/sshd.pam_include.2 sshd
+	fi
+
+	tweak_ssh_configs
+
+	doman contrib/ssh-copy-id.1
+	dodoc ChangeLog CREDITS OVERVIEW README* TODO sshd_config
+
+	diropts -m 0700
+	dodir /etc/skel/.ssh
+	rmdir "${ED}"/var/empty || die
+
+	systemd_dounit "${FILESDIR}"/sshd.socket
+	systemd_newunit "${FILESDIR}"/sshd.service.1 sshd.service
+	systemd_newunit "${FILESDIR}"/sshd_at.service.1 'sshd@.service'
+}
+
+pkg_preinst() {
+	if ! use ssl && has_version "${CATEGORY}/${PN}[ssl]"; then
+		show_ssl_warning=1
+	fi
+}
+
+pkg_postinst() {
+	local old_ver
+	for old_ver in ${REPLACING_VERSIONS}; do
+		if ver_test "${old_ver}" -lt "5.8_p1"; then
+			elog "Starting with openssh-5.8p1, the server will default to a newer key"
+			elog "algorithm (ECDSA).  You are encouraged to manually update your stored"
+			elog "keys list as servers update theirs.  See ssh-keyscan(1) for more info."
+		fi
+		if ver_test "${old_ver}" -lt "7.0_p1"; then
+			elog "Starting with openssh-6.7, support for USE=tcpd has been dropped by upstream."
+			elog "Make sure to update any configs that you might have.  Note that xinetd might"
+			elog "be an alternative for you as it supports USE=tcpd."
+		fi
+		if ver_test "${old_ver}" -lt "7.1_p1"; then #557388 #555518
+			elog "Starting with openssh-7.0, support for ssh-dss keys were disabled due to their"
+			elog "weak sizes.  If you rely on these key types, you can re-enable the key types by"
+			elog "adding to your sshd_config or ~/.ssh/config files:"
+			elog "	PubkeyAcceptedKeyTypes=+ssh-dss"
+			elog "You should however generate new keys using rsa or ed25519."
+
+			elog "Starting with openssh-7.0, the default for PermitRootLogin changed from 'yes'"
+			elog "to 'prohibit-password'.  That means password auth for root users no longer works"
+			elog "out of the box.  If you need this, please update your sshd_config explicitly."
+		fi
+		if ver_test "${old_ver}" -lt "7.6_p1"; then
+			elog "Starting with openssh-7.6p1, openssh upstream has removed ssh1 support entirely."
+			elog "Furthermore, rsa keys with less than 1024 bits will be refused."
+		fi
+		if ver_test "${old_ver}" -lt "7.7_p1"; then
+			elog "Starting with openssh-7.7p1, we no longer patch openssh to provide LDAP functionality."
+			elog "Install sys-auth/ssh-ldap-pubkey and use OpenSSH's \"AuthorizedKeysCommand\" option"
+			elog "if you need to authenticate against LDAP."
+			elog "See https://wiki.gentoo.org/wiki/SSH/LDAP_migration for more details."
+		fi
+		if ver_test "${old_ver}" -lt "8.2_p1"; then
+			ewarn "After upgrading to openssh-8.2p1 please restart sshd, otherwise you"
+			ewarn "will not be able to establish new sessions. Restarting sshd over a ssh"
+			ewarn "connection is generally safe."
+		fi
+		if ver_test "${old_ver}" -lt "9.2_p1-r1" && systemd_is_booted; then
+			ewarn "From openssh-9.2_p1-r1 the supplied systemd unit file defaults to"
+			ewarn "'Restart=on-failure', which causes the service to automatically restart if it"
+			ewarn "terminates with an unclean exit code or signal. This feature is useful for most users,"
+			ewarn "but it can increase the vulnerability of the system in the event of a future exploit."
+			ewarn "If you have a web-facing setup or are concerned about security, it is recommended to"
+			ewarn "set 'Restart=no' in your sshd unit file."
+		fi
+	done
+
+	if [[ -n ${show_ssl_warning} ]]; then
+		elog "Be aware that by disabling openssl support in openssh, the server and clients"
+		elog "no longer support dss/rsa/ecdsa keys.  You will need to generate ed25519 keys"
+		elog "and update all clients/servers that utilize them."
+	fi
+}
diff --git a/net-misc/putty/Manifest b/net-misc/putty/Manifest
index 3ccd4f0a20b9..ae12c35f3dab 100644
--- a/net-misc/putty/Manifest
+++ b/net-misc/putty/Manifest
@@ -1,6 +1,4 @@
-DIST putty-0.78.tar.gz 2811628 BLAKE2B 544fa7d3f7acfeb76cdb19e5ff3b60c81e4a1101ba16fab107d1f403745f792ab562d438d64a8a0a429b31ec426806c296a7b4e03916f8f32d2c227a54c32c71 SHA512 d7a3e2eabd5f1f65fc0f3f1ee0789c30fbe891b57f63ddeac0b92befcb6aecd4a748f04a21c76ee42d992deb77c2e1a0454a71cc620ef26fbf23af660bd84bb5
 DIST putty-0.80.tar.gz 2831433 BLAKE2B 95769ed372ee57f1cd0b9c9b26aab47c710b3eac2dd2f40b511179f1e06dae6c59ef5fd270eddc6b0531d8ed135897490ea029e0ca8c1febefe64743ddada341 SHA512 c8a6b6fa54ecd8bcf4ec274fef51343dd9996e6458b250b5555c4dc88ded25e87f97277da482c29858510e65635112d541f559ab683635bd950572d850129f90
 DIST putty-icons.tar.bz2 4878 BLAKE2B 589f1bace82e3fd202b70bd35661d2ec4ef383363f8ae6716d4a6828bd822ef624b0acde39354d3d837e2d2bb49a34dbb89e031c64c520cbc675cad79813acff SHA512 4e419a71e26770e159221f6b516e7210d29272917b4b9a9e0b67c72e73508b97278e56c82111b02e106c5d513c2561fec6da372b4b18246f29372ae618ff5f71
-EBUILD putty-0.78.ebuild 1737 BLAKE2B dba8b3d1142ab6b2eba92d78ca33a2c0a4cd0fbda6f50f60c47c2324011d3b428c4b56d6272d5fc7dd3b2b8a11a443b1a620012ddd2a01544792c368f4f9c400 SHA512 fc6a7e0bf203e35516f00e288b5d8c7f8e4858914b94e68d598c74733cf7e16d5d496d9c3e3d142a3e14da166a5d5a138d10d0f980ed687505ab483e16727e49
 EBUILD putty-0.80.ebuild 1756 BLAKE2B 8241951cf0e9aac1dccaa6196a30c34ea3fabd00dffcd78afbe5adac04b30441f07624f894ae4e76eeab730657ae20f45a0d05f27492989a3f748f90d6872029 SHA512 008afbb633cbb949cefd033dfce3170ea44cd45010dcf2675731e64173f3f9ec1027c1433d8fcb515d0ad90808ddd6b86d706e3f259bce71dc471e4c20250781
 MISC metadata.xml 887 BLAKE2B c51675758674360519d21f8722a4ea0815bfc56591a28e9026e4aa02b0046006ab87bfcd68f945184f1d82710d912a0f3557c34f4d43fc5fadd7ad7c38b5c3d3 SHA512 be79490eb1313d5f9d4b80dacc6e7727d44c1106da668869e58f106235ff6b074d17ad3fe41aa09c176bf713e17dddda6a73df728bfdfe752db6ccbf9690befa
diff --git a/net-misc/putty/putty-0.78.ebuild b/net-misc/putty/putty-0.78.ebuild
deleted file mode 100644
index dd68284f8bf4..000000000000
--- a/net-misc/putty/putty-0.78.ebuild
+++ /dev/null
@@ -1,91 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-inherit cmake desktop xdg-utils
-
-DESCRIPTION="A Free Telnet/SSH Client"
-HOMEPAGE="https://www.chiark.greenend.org.uk/~sgtatham/putty/"
-SRC_URI="https://dev.gentoo.org/~matthew/distfiles/${PN}-icons.tar.bz2"
-if [[ ${PV} == *9999 ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://git.tartarus.org/simon/putty.git"
-else
-	SRC_URI+=" https://the.earth.li/~sgtatham/${PN}/${PV}/${P}.tar.gz"
-	KEYWORDS="~alpha amd64 ~arm64 ~hppa ppc ppc64 sparc x86"
-fi
-LICENSE="MIT"
-
-SLOT="0"
-IUSE="debug doc +gtk gssapi"
-
-RDEPEND="
-	!net-misc/pssh
-	gtk? (
-		dev-libs/glib:2
-		x11-libs/gdk-pixbuf
-		x11-libs/gtk+:3[X]
-		x11-libs/libX11
-		x11-libs/pango
-	)
-	gssapi? ( virtual/krb5 )
-"
-DEPEND="
-	${RDEPEND}
-"
-BDEPEND="
-	dev-lang/perl
-	virtual/pkgconfig
-	doc? ( app-doc/halibut )
-"
-
-src_unpack() {
-	[[ ${PV} == *9999 ]] && git-r3_src_unpack
-	default
-}
-
-src_configure() {
-	cd "${S}"/unix || die
-	local mycmakeargs=(
-		-DPUTTY_DEBUG="$(usex debug)"
-		-DPUTTY_GSSAPI="$(usex gssapi DYNAMIC OFF)"
-		-DPUTTY_GTK_VERSION=$(usex gtk 3 '')
-		-DPUTTY_IPV6=yes
-	)
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile all doc
-}
-
-src_install() {
-	cmake_src_install
-
-	doman "${BUILD_DIR}"/doc/*.1
-
-	if use doc ; then
-		docinto html
-		dodoc "${BUILD_DIR}"/doc/html/*.html
-	fi
-
-	if use gtk ; then
-		local i
-		for i in 16 22 24 32 48 64 128 256; do
-			newicon -s ${i} \
-				"${WORKDIR}"/${PN}-icons/${PN}-${i}.png \
-				${PN}.png
-		done
-
-		# install desktop file provided by Gustav Schaffter in #49577
-		make_desktop_entry ${PN} PuTTY ${PN} Network
-	fi
-}
-
-pkg_postinst() {
-	use gtk && xdg_icon_cache_update
-}
-
-pkg_postrm() {
-	use gtk && xdg_icon_cache_update
-}