summaryrefslogtreecommitdiff
path: root/net-misc/icaclient
diff options
context:
space:
mode:
Diffstat (limited to 'net-misc/icaclient')
-rw-r--r--net-misc/icaclient/Manifest5
-rw-r--r--net-misc/icaclient/icaclient-22.12.0.12.ebuild276
-rw-r--r--net-misc/icaclient/metadata.xml3
3 files changed, 283 insertions, 1 deletions
diff --git a/net-misc/icaclient/Manifest b/net-misc/icaclient/Manifest
index e077a657b088..766bbbf6335d 100644
--- a/net-misc/icaclient/Manifest
+++ b/net-misc/icaclient/Manifest
@@ -6,12 +6,15 @@ AUX new_store.desktop 235 BLAKE2B 43bbf97a6982485e8b21f30c15889d64063ef0ce294b06
AUX selfservice.desktop 183 BLAKE2B 45d0830601ceac5159e239ec149cf3cdeabd43beb2ad6964935129fad6cd2c2e7c36cfc473e89b5db3b3b6cce2df909dd6013c3463631a7d868b470a49494285 SHA512 c4a2bdd83a29171c331b8adc98b33b8150fef5616d1fde8a0c9ccf1972b8ecc222dc1c0bc4e7779d93b851f44e79f5166138af7b7d36de964932ff3b63a4801b
AUX wfica.desktop 242 BLAKE2B 6e90bb02824a6319035814050919c55907b2104c65e2abcc7379a4c694a585945c2e10ada114c4dfb906ee3b1fa90a0251dcb1ec3aac1fb6015a2d2ecbef4452 SHA512 a233bbdfadaee080d8dda67ed81a60ef74902c1f2100cb08bc402186be23f1bbb82f84abb93da88d610d187a267f7db28e6bfebe689839c921ae5a94a4bdf1d7
DIST linuxx64-22.11.0.19.tar.gz 160489578 BLAKE2B ea6c5aab678746da64b0fa8329f5ffad871e5f42b4c6aa59f87daf6f8ca9a8901b690871376a79724fe835f9a9c026eb6bdf1ff55419ade62ebf472d25164dfa SHA512 5dab1616303f384d06ff6b2cc5c0ed0d9026745729ae503d03c7bddc6cebc536236c679d20886a94a2a241d1cfd96fd7fd766368ca779dacf0ff1785b36f5040
+DIST linuxx64-22.12.0.12.tar.gz 165269811 BLAKE2B 7735357f38d9438137792fc1d1febfdda6ca464fc43f573dffb4a33fffca052a78b8b61277cffd9287efcbc3823529e707140e7c9c1f9502c768528d2018b71d SHA512 bbe002d32e6d3819ab76ecef7fe7b62fff14da409d1b13c6edfc947cd46b0919d0f1972e7c1581d871bbe341ea50d3cf0da797f53f97b8e370610b37048f9a31
DIST linuxx64-22.5.0.16.tar.gz 162733197 BLAKE2B 32b4fd64d6bccf8a3be92e8f8ee59059839f31f4f771a6344fea320d2b635174c31c9e8d572a700568bab6032352fe72657dce1ee752327ed856370fa86acf9a SHA512 796ecbccc60995baae2082b5b275d7bf1482b19aed198de6d9f4083b2a3a68ff2fe73dfd1d3d33f0f885a157a77f20de008635eade36d5f9adff6b662aaefc1b
DIST linuxx64-22.9.0.21.tar.gz 160511942 BLAKE2B 43b671bc5c5eac968d2d6fd55615dce0d19206e9d64124b7e3dabf4311837c5cfe9ac25867b01795b9dc019f993a4507e852f84faba5116d58bdc4c85b784d85 SHA512 ebfd3fd51a61e0d419833fa0393a311b7c22331b6d950d985437ad992af96a96a9b1ea7d6c085e23593c6fcd46a8f946ca6c7b942d6919226bfc847a831fb95c
DIST linuxx86-22.11.0.19.tar.gz 146472406 BLAKE2B b685de8438087a67011d78cb6b56cdeae18185477b179bd2419e240709cf8333410f774facddc17cf23042a99deca5c9f77c24034e2d0b0b4decc57c38f326fb SHA512 6a0160a6e88eda43dcdfccdfb29fbb6f73f335b6a0f41dc2715a741be8c1019d49b5f6de68e67b5af0a03fd27cca748d0b9db25ef7a1e66e54770bf9716af3fa
+DIST linuxx86-22.12.0.12.tar.gz 147837116 BLAKE2B d5f1c53d1f2d2ecb95e67df256a667df733251a99dd4a5e9584554521c4f1b1fbd065dfd8b1c4ba344a543c5cd7dde4a939e3d4d82f658e7dae42c07527b645e SHA512 8e9c4262dcd7731b88ae43a663d5901a21a9ede2feed163b538f5fb475f0eba8768a08715db5e9c8fa809442140d1ef03d4d4e509cb83142bea806855615a6b3
DIST linuxx86-22.5.0.16.tar.gz 144032901 BLAKE2B 0f58adf7645eaba6ad75e126381ecfecf7434130b0e69bed75a0499386c5301475a48e414ce57aebdfeaea0cb6615ae93b48ecfdd0149851a56459d687d75bb7 SHA512 b94a3de41118d08f3ff549de33e80a85198a3db1349177cc5c921cdd45f1d5bb7e1ee338067602725a9bed16619216f552f98314d539915a251f020094ae3121
DIST linuxx86-22.9.0.21.tar.gz 146501445 BLAKE2B 823a9f063448351ada3a0c552c0175b540f9403c8ee844232ae23cccfd9199acd46e0a2c21e9c051c4a84f2700261e0a4d9b6fcbfc133c6cdbeca29fa256ba68 SHA512 7f2d39ef279c704004a371a4b95b48f2be4ed32de7406dd877ce585e22fb523a39b90a7e1cd968205d55c708ebe80fa1a85d9677cc1feb819b1843f445908f2b
EBUILD icaclient-22.11.0.19.ebuild 5779 BLAKE2B 20f8f808098a3efa8e16ffc24ba8bc9d0b669cc16751116ef4b9e535348e80cefa21d66e5d0a785f5c2f76540dd784b4e3933de98b97e801e4d845e7823c0e3a SHA512 16080d68c1ab83ae91b2cf80bc24f8713546802972d8b682d6e5697215e1741603d69a6b191900fb821e623db25a6c5828e746fbd59702ba1a0589c243608ccf
+EBUILD icaclient-22.12.0.12.ebuild 6216 BLAKE2B d55c476637608d0eab99f01593bb0d79e41fa51a5f3f124f466ea8c26fc2eee2690f36b1a33c70a1afc5cd32fb8680d981e70055cab4a56dfc321f1fd514a67f SHA512 18381e8435f322699d021d1a327c04346da55769666fceddc9ccc85763b23d27dd05ddc577fa45fa4dc49ffc0d265865361af74fdc17535093cdddd3f03c19ad
EBUILD icaclient-22.5.0.16-r1.ebuild 5600 BLAKE2B 4b79fe220715ff4464987a286e20cf7f22c69738a3e53e70deb92d77311181737e0767dbe6f3afe1c01ca33c8cd9ef0c47cc94cc5863d6f2611a49232d53871a SHA512 7148dce99640ca9fb715b5d7663af594502f29e16fd509f778b0460ff2f4e53673524b19642858923f3e079b7fbc76b4d71c176e77f1f1a824f0b920306a05e8
EBUILD icaclient-22.9.0.21-r2.ebuild 5779 BLAKE2B 20f8f808098a3efa8e16ffc24ba8bc9d0b669cc16751116ef4b9e535348e80cefa21d66e5d0a785f5c2f76540dd784b4e3933de98b97e801e4d845e7823c0e3a SHA512 16080d68c1ab83ae91b2cf80bc24f8713546802972d8b682d6e5697215e1741603d69a6b191900fb821e623db25a6c5828e746fbd59702ba1a0589c243608ccf
-MISC metadata.xml 396 BLAKE2B 87022ff667ea4915aaeb6bd69234d79f1030f0501ba2c6cbca8068905639f7797765b6b165a0cb5663f63f7d6089b73528745a3e3f413a02a023f66696f0ceb0 SHA512 8b03761bc34e251e177c940e1e61b0d7faba8651d7cc4f3971fe7928adbd9a3d7c4041474d404d966a5a0818066f0d64ce3c8b7f7fedebfed2132d338625b09d
+MISC metadata.xml 489 BLAKE2B 5277ab65457a889a26aa1c77279d68eef6fd4bd8d602e0ca1a06fac51b5576ce4b7d976bbbaeea555fc6ba2be42d686cfb425b03088bd5dff789edafbf11bb5c SHA512 4c69d7956c48402fa1fac2c5adede5079f8daf7c07a04f4d05af185dfa0d13417d54ce0ec063c77f966814e057f732c995e9e26e896e3c55a20d7c71db62f82f
diff --git a/net-misc/icaclient/icaclient-22.12.0.12.ebuild b/net-misc/icaclient/icaclient-22.12.0.12.ebuild
new file mode 100644
index 000000000000..399b2a4f22b1
--- /dev/null
+++ b/net-misc/icaclient/icaclient-22.12.0.12.ebuild
@@ -0,0 +1,276 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop wrapper xdg-utils
+
+DESCRIPTION="ICA Client for Citrix Presentation servers"
+HOMEPAGE="https://www.citrix.com/"
+SRC_URI="amd64? ( linuxx64-${PV}.tar.gz )
+ x86? ( linuxx86-${PV}.tar.gz )"
+
+LICENSE="icaclient"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="l10n_de l10n_es l10n_fr l10n_ja l10n_zh-CN hdx"
+RESTRICT="mirror strip fetch"
+
+ICAROOT="/opt/Citrix/ICAClient"
+
+QA_PREBUILT="${ICAROOT#/}/*"
+
+# we have binaries for two conflicting kerberos implementations
+# https://bugs.gentoo.org/792090
+# https://bugs.gentoo.org/775995
+REQUIRES_EXCLUDE="
+ libgssapi.so.3
+ libgssapi_krb5.so.2 libkrb5.so.3
+"
+# when using media-plugins/hdx-realtime-media-engine we better not ignore that
+REQUIRES_EXCLUDE="${REQUIRES_EXCLUDE}
+ !hdx? ( libunwind.so.1 )
+"
+# we have binaries which wouls still support gstreamer:0.10
+REQUIRES_EXCLUDE="${REQUIRES_EXCLUDE}
+ libgstapp-0.10.so.0
+ libgstbase-0.10.so.0
+ libgstinterfaces-0.10.so.0
+ libgstpbutils-0.10.so.0
+ libgstreamer-0.10.so.0
+"
+
+BEPEND="
+ hdx? ( >=media-plugins/hdx-realtime-media-engine-2.9.500.2802-r1 )
+"
+
+RDEPEND="
+ >=app-accessibility/at-spi2-core-2.46.0:2
+ app-crypt/libsecret
+ dev-libs/glib:2
+ dev-libs/libxml2
+ media-fonts/font-adobe-100dpi
+ media-fonts/font-misc-misc
+ media-fonts/font-cursor-misc
+ media-fonts/font-xfree86-type1
+ media-fonts/font-misc-ethiopic
+ media-libs/alsa-lib
+ media-libs/fontconfig
+ media-libs/freetype
+ media-libs/gst-plugins-base:1.0
+ media-libs/gstreamer:1.0
+ media-libs/libogg
+ media-libs/libpulse
+ media-libs/libvorbis
+ media-libs/mesa
+ media-libs/speex
+ net-libs/libsoup:2.4
+ net-libs/webkit-gtk:4
+ sys-apps/util-linux
+ sys-libs/libcxx
+ sys-libs/libcxxabi
+ sys-libs/zlib
+ virtual/krb5
+ virtual/libudev
+ x11-libs/cairo
+ x11-libs/gdk-pixbuf:2
+ x11-libs/gtk+:2
+ x11-libs/gtk+:3
+ x11-libs/libX11
+ x11-libs/libXaw
+ x11-libs/libXcomposite
+ x11-libs/libXdamage
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXinerama
+ x11-libs/libXmu
+ x11-libs/libXrender
+ x11-libs/libXt
+ x11-libs/pango
+ ${BDEPEND}
+ !hdx? ( !<media-plugins/hdx-realtime-media-engine-2.9.500.2802-r1 )
+"
+DEPENDS=""
+
+pkg_nofetch() {
+ elog "Download the client file ${A} from
+ https://www.citrix.com/downloads/workspace-app/"
+ elog "and place it into your DISTDIR directory."
+}
+
+pkg_setup() {
+ case ${ARCH} in
+ amd64)
+ ICAARCH=linuxx64
+ ;;
+ x86)
+ ICAARCH=linuxx86
+ ;;
+ *)
+ eerror "Given architecture is not supported by Citrix."
+ ;;
+ esac
+}
+
+src_unpack() {
+ default
+ mv "${WORKDIR}/${ICAARCH}/${ICAARCH}.cor" "${S}" || die
+}
+
+src_prepare() {
+ default
+ rm lib/UIDialogLibWebKit.so || die
+
+ cp nls/en/module.ini .
+ if use hdx; then
+ "${BROOT}${ICAROOT}"/rtme/RTMEconfig -install -ignoremm
+ mv new_module.ini module.ini
+ fi
+ mv module.ini config/
+}
+
+src_install() {
+ local bin tmpl dest
+
+ dodir "${ICAROOT}"
+
+ exeinto "${ICAROOT}"
+ doexe *.DLL libproxy.so wfica AuthManagerDaemon PrimaryAuthManager selfservice ServiceRecord
+
+ exeinto "${ICAROOT}"/lib
+ doexe lib/*.so
+
+ for dest in "${ICAROOT}"{,/nls/en{,.UTF-8}} ; do
+ insinto "${dest}"
+ doins nls/en.UTF-8/eula.txt
+ done
+
+ insinto "${ICAROOT}"
+ doins -r usb
+
+ insinto "${ICAROOT}"/config
+ doins config/*
+ for tmpl in {appsrv,wfclient}.template ; do
+ newins nls/en/${tmpl} ${tmpl/template/ini}
+ done
+ touch "${ED}/${ICAROOT}"/config/.server || die
+
+ insinto "${ICAROOT}"/gtk
+ doins gtk/*
+
+ insinto "${ICAROOT}"/gtk/glade
+ doins gtk/glade/*
+
+ insinto "${ICAROOT}"/site
+ doins -r site/*
+
+ dodir "${ICAROOT}"/help
+
+ insinto "${ICAROOT}"/config/usertemplate
+ doins config/usertemplate/*
+
+ local lang LANGCODES=( en )
+ use l10n_de && LANGCODES+=( de )
+ use l10n_es && LANGCODES+=( es )
+ use l10n_fr && LANGCODES+=( fr )
+ use l10n_ja && LANGCODES+=( ja )
+ use l10n_zh-CN && LANGCODES+=( zh_CN )
+
+ for lang in ${LANGCODES[@]} ; do
+ insinto "${ICAROOT}"/nls/${lang}
+ doins nls/${lang}/*
+
+ insinto "${ICAROOT}"/nls/$lang/UTF-8
+ doins nls/${lang}.UTF-8/*
+
+ insinto "${ICAROOT}"/nls/${lang}/LC_MESSAGES
+ doins nls/${lang}/LC_MESSAGES/*
+
+ insinto "${ICAROOT}"/nls/${lang}
+ dosym UTF-8 "${ICAROOT}"/nls/${lang}/utf8
+
+ for tmpl in {appsrv,wfclient}.template ; do
+ cp "${ED}/${ICAROOT}"/nls/${lang}/${tmpl} \
+ "${ED}/${ICAROOT}"/nls/${lang}/${tmpl/template/ini} \
+ || die
+ done
+ done
+
+ insinto "${ICAROOT}"/nls
+ dosym en /opt/Citrix/ICAClient/nls/C
+
+ insinto "${ICAROOT}"/icons
+ doins icons/*
+
+ insinto "${ICAROOT}"/keyboard
+ doins keyboard/*
+
+ cp -a util "${ED}/${ICAROOT}" || die
+ test -f util/HdxRtcEngine && fperms 0755 "${ICAROOT}"/util/HdxRtcEngine
+
+ rm -r "${S}"/keystore/cacerts || die
+ dosym ../../../../etc/ssl/certs "${ICAROOT}"/keystore/cacerts
+
+ local other_files=(
+ icasessionmgr
+ NativeMessagingHost
+ UtilDaemon
+ )
+
+ exeinto "${ICAROOT}"
+ for bin in ${other_files[@]} ; do
+ doexe ${bin}
+ done
+
+ # https://bugs.gentoo.org/655922
+ dosym gst_play1.0 "${ICAROOT}"/util/gst_play
+ dosym gst_read1.0 "${ICAROOT}"/util/gst_read
+ dosym libgstflatstm1.0.so "${ICAROOT}"/util/libgstflatstm.so
+
+ doenvd "${FILESDIR}"/10ICAClient
+
+ for bin in configmgr conncenter new_store ; do
+ make_wrapper ${bin} "${ICAROOT}"/util/${bin} . "${ICAROOT}"/util
+ done
+
+ for bin in selfservice wfica ; do
+ make_wrapper ${bin} "${ICAROOT}"/${bin} . "${ICAROOT}"
+ done
+
+ dodir /etc/revdep-rebuild/
+ echo "SEARCH_DIRS_MASK=\"${ICAROOT}\"" \
+ > "${ED}"/etc/revdep-rebuild/70icaclient
+
+ insinto "${ICAROOT}"/pkginf
+ newins "${WORKDIR}"/PkgId Ver.core."${ICAARCH}"
+
+ # 651926
+ domenu "${FILESDIR}"/*.desktop
+
+ insinto /usr/share/mime/packages
+ doins desktop/Citrix-mime_types.xml
+}
+
+pkg_preinst() {
+ # previous versions of the ebuild created that and left it around
+ # we own it now and avoid conflict warnings with this
+ rm -f "${ROOT}${ICAROOT}/config/module.ini"
+}
+
+pkg_postinst() {
+ xdg_desktop_database_update
+ xdg_mimeinfo_database_update
+
+ if ! use hdx; then
+ if [ -x "${ROOT}${ICAROOT}"/rtme/RTMEconfig ]; then
+ ewarn "Starting from 22.12.0.12 you have to set USE=hdx if you want"
+ ewarn "to use media-plugins/hdx-realtime-media-engine. Which does"
+ ewarn "not need to be explicitly installed anymore."
+ fi
+ fi
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_mimeinfo_database_update
+}
diff --git a/net-misc/icaclient/metadata.xml b/net-misc/icaclient/metadata.xml
index d86008401e21..83d0f6942931 100644
--- a/net-misc/icaclient/metadata.xml
+++ b/net-misc/icaclient/metadata.xml
@@ -9,4 +9,7 @@
<email>proxy-maint@gentoo.org</email>
<name>Proxy Maintainers</name>
</maintainer>
+ <use>
+ <flag name="hdx">Install and enable hdx-realtime-media-engine plugin</flag>
+ </use>
</pkgmetadata>
generated by cgit v1.2.3 (git 2.25.1) at 2024-07-02 15:49:59 +0000