4 files changed, 265 insertions, 4 deletions
diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index dbde11b7181a..bd5c819475be 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -1,6 +1,8 @@
 AUX wireshark-2.6.0-redhat.patch 248 BLAKE2B a3cc5af29cea1b46cc8456c80a1ddf3a0db464f1274beba49c440af831d708bf251ad7481231f27bd7d7f99cf50f964e7f8aa80ce3c0f4d3b06f00ce624f7347 SHA512 92d498c7b6c3a4ae461f5bbca090943dbd7a3151628eebd4b212f3d9eca133260fe46bc72c6bec8444a83517d7a69c334257c61f9fd8e1256f71dd70241e3f66
 AUX wireshark-99999999-ui-needs-wiretap.patch 211 BLAKE2B f27c7ecdc3ee769020ad5d361fb335e6d70bcedb6ff0d19b48df2c1739b636f5585d329d50a9da0c741caed7c42cdc758668312b851d4eec440d782e2e9b1d24 SHA512 5ad342a062c560f729a7ec2b667aa88e2b9b3c6d547d9ecb96e3dc30224a4d766d1bc8806b08f608c5514309cc8bdf6903f39e232afe21003afe9f1e88082ea3
 DIST wireshark-3.4.0.tar.xz 32502760 BLAKE2B 5d8106f36cc3a1425fd472f7ba645b2a07bfb93c96178a98f90676f39cad38089b625d7d6725ecfaf67bfc78aba3476567b9bf390d6f0dd838537eb81bc4aaa7 SHA512 02070db23c64e1efe42b83cdcd7b52fb9b247e653da0aa12dc21a4283272fea0a135f4b0c5641197840bef88e52785d64a860c9fcfe1bcbaceb016c5258c9649
-EBUILD wireshark-3.4.0.ebuild 6897 BLAKE2B 40060ac8da3fe5d0bb0a324f44c41816018b45f659caa329e1e391b69f055cedb9b02d8cb1f1201c9b5738d3e09688b8fae2a9c51f83432896007880964e8e9d SHA512 b0cb8dfa42527a9a6f69d36b23514d7f374d08c090fdee37f57fbf55ab39518df309160561da64a661a6f2e9ca6f3953f46d42a79b491f3c59c94ce8a25e109e
-EBUILD wireshark-99999999.ebuild 6787 BLAKE2B 37a68da765e48fa4fd7105bb4c57ca7e88549a4044d92e45aa0c9fefff95f0e2efbc018edb9797cbd52074cd4b92d1eaea9963dfe2262eda2b2d712b99d4fde7 SHA512 49cb20297b5321cfb427783fec1d202c5ea236e772a3ebc5154e0919702f29867478d861d4f835005925979e45e7bfe250700a15bdc4489109df076265464624
+DIST wireshark-3.4.1.tar.xz 32470004 BLAKE2B aa2c3e56df4232b087d09a52209eec1e91a10ab125f6fb973171771d86d349ddf76bef3da089f0d6740c67883009fb77c5760c1141c99a056e7a36fe8ae5c088 SHA512 a968158a5a22d04a9bf3b060246f7579210a8106e06184411fd00dad69e030c10aecfa579c09dcca11fb659e0a1de4773951578cb3697dd2dc8e5153d3892728
+EBUILD wireshark-3.4.0.ebuild 6898 BLAKE2B 3bdaa80868d870e2a5fc8f71cb53431e865a3f9f28bb893651e11b04d1ccab30dd4bb29dba30129000dc3b401ab5ab2d4a22a6e7c4d7c603a309206f42b310b0 SHA512 bc0c37dfc811d0f425079aad51a86cf793d7c8eca6e083a674e2df9f321c87c45d386dc5ba8153dbe999a2ee89140939dffa5fe660b858534f1cb48159e3f531
+EBUILD wireshark-3.4.1.ebuild 6901 BLAKE2B 9d380e47c2cfe7d3f14a842e802baf99b200ca01999ce46d090bd32ee941a205838120885aa157d40ca0d89ddfbfa1733aabb285e03ae8e3a87118374981d7e8 SHA512 d930a68747eaa2b4c4350ce2274b7377e56f71b8c010e4fdd73944f3e44e8f0ed3643804de0e547cb4cd150954e82ab51ebe55357e75b198a2901b6e3a65b869
+EBUILD wireshark-99999999.ebuild 6788 BLAKE2B 7d04031c8fb62d7dcb7ea915205bd7d00dc1d3cad0066a2a0443fe26d6af2400ef85552211c110eaec7c411e00bc4fa7634dc2a6456eaecb7959363c83ab2a1c SHA512 b59f2d1e5e4bd82a280d2ed7ce546ee9d43ed09251f71ff01efb5be38ca524bd8fbbf061a4ba4f823e829a92f6891e2180e01dbfee8bba659ab08764d9a737ff
 MISC metadata.xml 5327 BLAKE2B f3e047c03a849bfdfded710eccb1e05fbcf00407bbe3eb2a2b63b562e7d583a3ca66de214c17350bec56451f69453fc819921119c7954ef6ea01cfe134ac4783 SHA512 9e514634a6017be1e5c2752c107c33f231e019ce9ffd239042d8f3d426263aea88052748749b7359a9c4c2e591d379c8faf895192358cea20601887b784529ba
diff --git a/net-analyzer/wireshark/wireshark-3.4.0.ebuild b/net-analyzer/wireshark/wireshark-3.4.0.ebuild
index 21e823418e48..ddabdfd5f7b5 100644
--- a/net-analyzer/wireshark/wireshark-3.4.0.ebuild
+++ b/net-analyzer/wireshark/wireshark-3.4.0.ebuild
@@ -36,7 +36,7 @@ CDEPEND="
 	ilbc? ( media-libs/libilbc )
 	kerberos? ( virtual/krb5 )
 	libxml2? ( dev-libs/libxml2 )
-	lua? ( >=dev-lang/lua-5.1:* )
+	lua? ( >=dev-lang/lua-5.1:0= )
 	lz4? ( app-arch/lz4 )
 	maxminddb? ( dev-libs/libmaxminddb )
 	minizip? ( sys-libs/zlib[minizip] )
diff --git a/net-analyzer/wireshark/wireshark-3.4.1.ebuild b/net-analyzer/wireshark/wireshark-3.4.1.ebuild
new file mode 100644
index 000000000000..b72304eb72c8
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-3.4.1.ebuild
@@ -0,0 +1,259 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit fcaps flag-o-matic multilib python-any-r1 qmake-utils xdg-utils cmake
+
+DESCRIPTION="A network protocol analyzer formerly known as ethereal"
+HOMEPAGE="https://www.wireshark.org/"
+SRC_URI="https://www.wireshark.org/download/src/all-versions/${P/_/}.tar.xz"
+LICENSE="GPL-2"
+
+SLOT="0/${PV}"
+KEYWORDS="~alpha amd64 ~arm arm64 ~hppa ~ia64 ~ppc64 ~x86"
+IUSE="
+	androiddump bcg729 brotli +capinfos +captype ciscodump +dftest doc dpauxmon
+	+dumpcap +editcap http2 ilbc kerberos libxml2 lto lua lz4 maxminddb
+	+mergecap +minizip +netlink opus +plugins plugin-ifdemo +pcap +qt5 +randpkt
+	+randpktdump +reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl
+	sdjournal test +text2pcap tfshark +tshark +udpdump zlib +zstd
+"
+S=${WORKDIR}/${P/_/}
+
+CDEPEND="
+	acct-group/pcap
+	>=dev-libs/glib-2.32:2
+	>=net-dns/c-ares-1.5
+	dev-libs/libgcrypt:0
+	bcg729? ( media-libs/bcg729 )
+	brotli? ( app-arch/brotli )
+	ciscodump? ( >=net-libs/libssh-0.6 )
+	filecaps? ( sys-libs/libcap )
+	http2? ( net-libs/nghttp2 )
+	ilbc? ( media-libs/libilbc )
+	kerberos? ( virtual/krb5 )
+	libxml2? ( dev-libs/libxml2 )
+	lua? ( >=dev-lang/lua-5.1:0= )
+	lz4? ( app-arch/lz4 )
+	maxminddb? ( dev-libs/libmaxminddb )
+	minizip? ( sys-libs/zlib[minizip] )
+	netlink? ( dev-libs/libnl:3 )
+	opus? ( media-libs/opus )
+	pcap? ( net-libs/libpcap )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtmultimedia:5
+		dev-qt/qtprintsupport:5
+		dev-qt/qtwidgets:5
+		x11-misc/xdg-utils
+	)
+	sbc? ( media-libs/sbc )
+	sdjournal? ( sys-apps/systemd )
+	smi? ( net-libs/libsmi )
+	snappy? ( app-arch/snappy )
+	spandsp? ( media-libs/spandsp )
+	sshdump? ( >=net-libs/libssh-0.6 )
+	ssl? ( net-libs/gnutls:= )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd )
+"
+# We need perl for `pod2html`. The rest of the perl stuff is to block older
+# and broken installs. #455122
+DEPEND="
+	${CDEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	dev-lang/perl
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-ruby/asciidoctor
+	)
+	qt5? (
+		dev-qt/linguist-tools:5
+	)
+	test? (
+		dev-python/pytest
+		dev-python/pytest-xdist
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	qt5? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+REQUIRED_USE="
+	plugin-ifdemo? ( plugins )
+"
+RESTRICT="test"
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.6.0-redhat.patch
+	"${FILESDIR}"/${PN}-99999999-ui-needs-wiretap.patch
+)
+
+src_configure() {
+	local mycmakeargs
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				mycmakeargs+=( -DENABLE_GNUTLS=$(usex ssl) )
+				;;
+		esac
+	fi
+
+	if use qt5; then
+		export QT_MIN_VERSION=5.3.0
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	python_setup
+
+	mycmakeargs+=(
+		$(use androiddump && use pcap && echo -DEXTCAP_ANDROIDDUMP_LIBPCAP=yes)
+		$(usex qt5 LRELEASE=$(qt5_get_bindir)/lrelease '')
+		$(usex qt5 MOC=$(qt5_get_bindir)/moc '')
+		$(usex qt5 RCC=$(qt5_get_bindir)/rcc '')
+		$(usex qt5 UIC=$(qt5_get_bindir)/uic '')
+		-DBUILD_androiddump=$(usex androiddump)
+		-DBUILD_capinfos=$(usex capinfos)
+		-DBUILD_captype=$(usex captype)
+		-DBUILD_ciscodump=$(usex ciscodump)
+		-DBUILD_dftest=$(usex dftest)
+		-DBUILD_dpauxmon=$(usex dpauxmon)
+		-DBUILD_dumpcap=$(usex dumpcap)
+		-DBUILD_editcap=$(usex editcap)
+		-DBUILD_mergecap=$(usex mergecap)
+		-DBUILD_mmdbresolve=$(usex maxminddb)
+		-DBUILD_randpkt=$(usex randpkt)
+		-DBUILD_randpktdump=$(usex randpktdump)
+		-DBUILD_reordercap=$(usex reordercap)
+		-DBUILD_sdjournal=$(usex sdjournal)
+		-DBUILD_sharkd=$(usex sharkd)
+		-DBUILD_sshdump=$(usex sshdump)
+		-DBUILD_text2pcap=$(usex text2pcap)
+		-DBUILD_tfshark=$(usex tfshark)
+		-DBUILD_tshark=$(usex tshark)
+		-DBUILD_udpdump=$(usex udpdump)
+		-DBUILD_wireshark=$(usex qt5)
+		-DDISABLE_WERROR=yes
+		-DENABLE_BCG729=$(usex bcg729)
+		-DENABLE_BROTLI=$(usex brotli)
+		-DENABLE_CAP=$(usex filecaps caps)
+		-DENABLE_GNUTLS=$(usex ssl)
+		-DENABLE_ILBC=$(usex ilbc)
+		-DENABLE_KERBEROS=$(usex kerberos)
+		-DENABLE_LIBXML2=$(usex libxml2)
+		-DENABLE_LTO=$(usex lto)
+		-DENABLE_LUA=$(usex lua)
+		-DENABLE_LZ4=$(usex lz4)
+		-DENABLE_MINIZIP=$(usex minizip)
+		-DENABLE_NETLINK=$(usex netlink)
+		-DENABLE_NGHTTP2=$(usex http2)
+		-DENABLE_OPUS=$(usex opus)
+		-DENABLE_PCAP=$(usex pcap)
+		-DENABLE_PLUGINS=$(usex plugins)
+		-DENABLE_PLUGIN_IFDEMO=$(usex plugin-ifdemo)
+		-DENABLE_SBC=$(usex sbc)
+		-DENABLE_SMI=$(usex smi)
+		-DENABLE_SNAPPY=$(usex snappy)
+		-DENABLE_SPANDSP=$(usex spandsp)
+		-DENABLE_ZLIB=$(usex zlib)
+		-DENABLE_ZSTD=$(usex zstd)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_build test-programs
+
+	myctestargs=( --disable-capture --skip-missing-programs=all --verbose )
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README* doc/randpkt.txt doc/README*
+
+	# install headers
+	insinto /usr/include/wireshark
+	doins ws_diag_control.h ws_symbol_export.h \
+		"${BUILD_DIR}"/config.h "${BUILD_DIR}"/version.h
+
+	local dir dirs=(
+		epan
+		epan/crypt
+		epan/dfilter
+		epan/dissectors
+		epan/ftypes
+		epan/wmem
+		wiretap
+		wsutil
+	)
+	for dir in "${dirs[@]}"
+	do
+		insinto /usr/include/wireshark/${dir}
+		doins ${dir}/*.h
+	done
+
+	#with the above this really shouldn't be needed, but things may be looking
+	# in wiretap/ instead of wireshark/wiretap/
+	insinto /usr/include/wiretap
+	doins wiretap/wtap.h
+
+	if use qt5; then
+		local s
+		for s in 16 32 48 64 128 256 512 1024; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/apps
+			newins image/wsicon${s}.png wireshark.png
+		done
+		for s in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/mimetypes
+			newins image/WiresharkDoc-${s}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	if [[ -d "${D}"/usr/share/appdata ]]; then
+		rm -r "${D}"/usr/share/appdata || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+
+	# Add group for users allowed to sniff.
+	chgrp pcap "${EROOT}"/usr/bin/dumpcap
+
+	if use dumpcap && use pcap; then
+		fcaps -o 0 -g pcap -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
+	ewarn "add yourself to the pcap group. This security measure ensures"
+	ewarn "that only trusted users are allowed to sniff your traffic."
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
diff --git a/net-analyzer/wireshark/wireshark-99999999.ebuild b/net-analyzer/wireshark/wireshark-99999999.ebuild
index bb74c3376075..25d08cbda033 100644
--- a/net-analyzer/wireshark/wireshark-99999999.ebuild
+++ b/net-analyzer/wireshark/wireshark-99999999.ebuild
@@ -35,7 +35,7 @@ CDEPEND="
 	ilbc? ( media-libs/libilbc )
 	kerberos? ( virtual/krb5 )
 	libxml2? ( dev-libs/libxml2 )
-	lua? ( >=dev-lang/lua-5.1:* )
+	lua? ( >=dev-lang/lua-5.1:0= )
 	lz4? ( app-arch/lz4 )
 	maxminddb? ( dev-libs/libmaxminddb )
 	minizip? ( sys-libs/zlib[minizip] )