1 files changed, 64 insertions, 0 deletions
diff --git a/net-analyzer/prelude-lml/prelude-lml-5.2.0.ebuild b/net-analyzer/prelude-lml/prelude-lml-5.2.0.ebuild
new file mode 100644
index 000000000000..554623ae6606
--- /dev/null
+++ b/net-analyzer/prelude-lml/prelude-lml-5.2.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd tmpfiles
+
+DESCRIPTION="The prelude log analyzer"
+HOMEPAGE="https://www.prelude-siem.org"
+SRC_URI="https://www.prelude-siem.org/pkg/src/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="icu ssl"
+
+RDEPEND="dev-libs/libpcre
+	>=dev-libs/libprelude-5.2.0
+	<dev-libs/libprelude-6
+	icu? ( dev-libs/icu:= )
+	ssl? ( net-libs/gnutls:= )"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.1.0-run.patch"
+	"${FILESDIR}/${PN}-3.0.0-conf.patch"
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--localstatedir="${EPREFIX}/var"
+		$(use_with ssl libgnutls-prefix)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	rm -rv "${ED}/run" || die "rm failed"
+	keepdir /var/${PN}
+	keepdir /var/spool/prelude/prelude-lml
+
+	find "${D}" -name '*.la' -delete || die
+
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	newtmpfiles "${FILESDIR}/${PN}.run" "${PN}.conf"
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+}
+
+pkg_postinst() {
+	tmpfiles_process "${PN}.conf"
+}