summaryrefslogtreecommitdiff
path: root/media-video/mkvtoolnix
diff options
context:
space:
mode:
Diffstat (limited to 'media-video/mkvtoolnix')
-rw-r--r--media-video/mkvtoolnix/Manifest4
-rw-r--r--media-video/mkvtoolnix/mkvtoolnix-37.0.0.ebuild118
-rw-r--r--media-video/mkvtoolnix/mkvtoolnix-9999.ebuild60
3 files changed, 151 insertions, 31 deletions
diff --git a/media-video/mkvtoolnix/Manifest b/media-video/mkvtoolnix/Manifest
index d85c84aceb67..8725c3994b33 100644
--- a/media-video/mkvtoolnix/Manifest
+++ b/media-video/mkvtoolnix/Manifest
@@ -1,4 +1,6 @@
DIST mkvtoolnix-35.0.0.tar.xz 7297244 BLAKE2B 9a7cd015b00fe46f165903b8b6f9317489548aa9a352c85727296ee0638506336028231b115a9270388a4ede1a088a4bdba16156600341c51bd5a2ae557b181f SHA512 aa109be9da3f0bd119d9315b9ea136d3c1532d0f351c5a052dcc7ad67a4dcec9d8fec69a0c9358790abfcb6eeaee47fad4af2a0506bef39cfd5c8466f90bdf98
+DIST mkvtoolnix-37.0.0.tar.xz 7307984 BLAKE2B 4ee59d6ed186e7181733f5723fc8ab5abed5056c7562cf646b123f0e4d9e6b191176feab549231d8210b669d4cec36aaa6e33bf1b666b92ba471696d83e98c8e SHA512 196f8d12f36d95d077b8afeda4d651fe7fe5a0d6c9e71a49608732cbf6d68052681ec855875ed4a79e8aa0589502f4475a4306eaa9464523288a1af740b84df8
EBUILD mkvtoolnix-35.0.0.ebuild 2673 BLAKE2B 2e0f0339434a91911d6b09541c1e1ea0a33deb365e82c13cd97a976c0ffff08a340d2402bd5a6949d24a9565e2406c5403a684f582068eb505494938fda9a89e SHA512 55744b23a1f061e14601d157309615bed32a282a0d6c3b84aa2dd1212cdcaf264d6e6b28f345bfbef16759c01e3f88e20457ccb0de40ee2d9f86569dadbb5f06
-EBUILD mkvtoolnix-9999.ebuild 2700 BLAKE2B 5022fb5fe50f1ad679460b31422358a7e225221faaf0c5a7a222b92cdb78f6e2f875b84b7ac538d7304e30c2d59c29f9d2c854d7532f8dad62cc1a5dc8a5bd3a SHA512 7ea4aa4ad28297f92910e7997faa97923c02e704d8f066fdb3fc8f5bbb47e91bbd94fa504fca0df6d1de57b06406910e2b1dfc5e9a6762122fc21884d795fb7d
+EBUILD mkvtoolnix-37.0.0.ebuild 2610 BLAKE2B 49af0fe580bda9d5317933a9ff81ca2083a52003dc1ae840eb15993910901dabc760c907eedb568a608b1f21ba492dab7538b08a51381f4a72b879a373ce86a6 SHA512 bd3b475b421f12790d703ade528eade5640d97591a0fbeedb2387690bfddbe1a395e15e75fce6de6b01aaacb7d25874abae9750b5c964d24761efae693e0a563
+EBUILD mkvtoolnix-9999.ebuild 2610 BLAKE2B 49af0fe580bda9d5317933a9ff81ca2083a52003dc1ae840eb15993910901dabc760c907eedb568a608b1f21ba492dab7538b08a51381f4a72b879a373ce86a6 SHA512 bd3b475b421f12790d703ade528eade5640d97591a0fbeedb2387690bfddbe1a395e15e75fce6de6b01aaacb7d25874abae9750b5c964d24761efae693e0a563
MISC metadata.xml 255 BLAKE2B 84855d12acedab301e8e709820ef74f658689209ce914cad2c71d11f4248a7d3356109d93573ed675698031eca1e0b6e0372a61c2a43a9f09840e295f94b74ef SHA512 92b56f4d9c86ad69341e67e8cc74db0bd068e45afdf2f3d3f9ea410fc5e64f3476143b656f2cb3d26b97ae01a967d71766952eba22e2278aab907c20b00ae0e9
diff --git a/media-video/mkvtoolnix/mkvtoolnix-37.0.0.ebuild b/media-video/mkvtoolnix/mkvtoolnix-37.0.0.ebuild
new file mode 100644
index 000000000000..5fa946801729
--- /dev/null
+++ b/media-video/mkvtoolnix/mkvtoolnix-37.0.0.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic toolchain-funcs multiprocessing qmake-utils xdg
+
+if [[ ${PV} == *9999 ]] ; then
+ EGIT_REPO_URI="https://gitlab.com/mbunkus/mkvtoolnix.git"
+ EGIT_SUBMODULES=()
+ inherit autotools git-r3
+else
+ SRC_URI="https://mkvtoolnix.download/sources/${P}.tar.xz"
+ KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="https://mkvtoolnix.download/ https://gitlab.com/mbunkus/mkvtoolnix"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="debug nls pch test qt5"
+
+# check NEWS.md for build system changes entries for boost/libebml/libmatroska
+# version requirement updates and other packaging info
+RDEPEND="
+ dev-libs/boost:=
+ >=dev-libs/libebml-1.3.7:=
+ >=dev-libs/libfmt-5.3.0:=
+ dev-libs/pugixml:=
+ media-libs/flac:=
+ >=media-libs/libmatroska-1.5.0:=
+ media-libs/libogg:=
+ media-libs/libvorbis:=
+ sys-apps/file
+ sys-libs/zlib
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtdbus:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtconcurrent:5
+ dev-qt/qtmultimedia:5
+ app-text/cmark:0=
+ )
+"
+DEPEND="${RDEPEND}
+ dev-cpp/nlohmann_json
+ dev-libs/utfcpp
+ test? ( dev-cpp/gtest )
+"
+BDEPEND="
+ app-text/docbook-xsl-stylesheets
+ dev-libs/libxslt
+ dev-ruby/rake
+ virtual/pkgconfig
+ nls? (
+ sys-devel/gettext
+ app-text/po4a
+ )
+"
+
+src_prepare() {
+ xdg_src_prepare
+ if [[ ${PV} == *9999 ]]; then
+ ./autogen.sh || die
+ fi
+
+ # remove bundled libs
+ rm -r lib/{fmt,libebml,libmatroska,nlohmann-json,pugixml,utf8-cpp} || die
+}
+
+src_configure() {
+ # bug 692322, use system dev-libs/utfcpp
+ append-cppflags -I"${ESYSROOT}"/usr/include/utf8cpp
+
+ local myeconfargs=(
+ $(use_enable debug)
+ $(usex pch "" --disable-precompiled-headers)
+ $(use_enable qt5 qt)
+ $(use_with nls gettext)
+ $(usex nls "" --with-po4a-translate=false)
+ --disable-update-check
+ --disable-optimization
+ --with-boost="${ESYSROOT}"/usr
+ --with-boost-libdir="${ESYSROOT}"/usr/$(get_libdir)
+ )
+
+ if use qt5 ; then
+ # ac/qt5.m4 finds default Qt version set by qtchooser, bug #532600
+ myeconfargs+=(
+ --with-moc=$(qt5_get_bindir)/moc
+ --with-uic=$(qt5_get_bindir)/uic
+ --with-rcc=$(qt5_get_bindir)/rcc
+ --with-qmake=$(qt5_get_bindir)/qmake
+ )
+ fi
+
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ rake V=1 -j$(makeopts_jobs) || die
+}
+
+src_test() {
+ rake V=1 -j$(makeopts_jobs) tests:unit || die
+ rake V=1 -j$(makeopts_jobs) tests:run_unit || die
+}
+
+src_install() {
+ DESTDIR="${D}" rake -j$(makeopts_jobs) install || die
+
+ einstalldocs
+ dodoc NEWS.md
+ doman doc/man/*.1
+}
diff --git a/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild b/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
index c91b87e7c617..5fa946801729 100644
--- a/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
+++ b/media-video/mkvtoolnix/mkvtoolnix-9999.ebuild
@@ -1,15 +1,17 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
-EAPI=6
-inherit toolchain-funcs versionator multiprocessing qmake-utils xdg
+EAPI=7
-if [[ ${PV} == "9999" ]] ; then
+inherit flag-o-matic toolchain-funcs multiprocessing qmake-utils xdg
+
+if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://gitlab.com/mbunkus/mkvtoolnix.git"
- inherit git-r3
+ EGIT_SUBMODULES=()
+ inherit autotools git-r3
else
SRC_URI="https://mkvtoolnix.download/sources/${P}.tar.xz"
- KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+ KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
fi
DESCRIPTION="Tools to create, alter, and inspect Matroska files"
@@ -22,14 +24,14 @@ IUSE="debug nls pch test qt5"
# check NEWS.md for build system changes entries for boost/libebml/libmatroska
# version requirement updates and other packaging info
RDEPEND="
- >=dev-libs/libfmt-5.3.0:=
- >=dev-libs/boost-1.49.0:=
+ dev-libs/boost:=
>=dev-libs/libebml-1.3.7:=
- dev-libs/pugixml
- media-libs/flac
+ >=dev-libs/libfmt-5.3.0:=
+ dev-libs/pugixml:=
+ media-libs/flac:=
>=media-libs/libmatroska-1.5.0:=
- media-libs/libogg
- media-libs/libvorbis
+ media-libs/libogg:=
+ media-libs/libvorbis:=
sys-apps/file
sys-libs/zlib
qt5? (
@@ -46,35 +48,33 @@ RDEPEND="
DEPEND="${RDEPEND}
dev-cpp/nlohmann_json
dev-libs/utfcpp
+ test? ( dev-cpp/gtest )
+"
+BDEPEND="
+ app-text/docbook-xsl-stylesheets
+ dev-libs/libxslt
dev-ruby/rake
virtual/pkgconfig
- dev-libs/libxslt
- app-text/docbook-xsl-stylesheets
nls? (
sys-devel/gettext
app-text/po4a
)
- test? ( dev-cpp/gtest )
"
-DOCS="AUTHORS NEWS.md README.md"
-
-pkg_pretend() {
- # https://bugs.gentoo.org/419257
- local ver=4.6
- local msg="You need at least GCC ${ver}.x for C++11 range-based 'for' and nullptr support."
- if ! version_is_at_least ${ver} $(gcc-version); then
- eerror ${msg}
- die ${msg}
- fi
-}
-
src_prepare() {
xdg_src_prepare
- [[ ${PV} == "9999" ]] && { ./autogen.sh || die; }
+ if [[ ${PV} == *9999 ]]; then
+ ./autogen.sh || die
+ fi
+
+ # remove bundled libs
+ rm -r lib/{fmt,libebml,libmatroska,nlohmann-json,pugixml,utf8-cpp} || die
}
src_configure() {
+ # bug 692322, use system dev-libs/utfcpp
+ append-cppflags -I"${ESYSROOT}"/usr/include/utf8cpp
+
local myeconfargs=(
$(use_enable debug)
$(usex pch "" --disable-precompiled-headers)
@@ -83,9 +83,8 @@ src_configure() {
$(usex nls "" --with-po4a-translate=false)
--disable-update-check
--disable-optimization
- --docdir="${EPREFIX}"/usr/share/doc/${PF}
- --with-boost="${EPREFIX}"/usr
- --with-boost-libdir="${EPREFIX}"/usr/$(get_libdir)
+ --with-boost="${ESYSROOT}"/usr
+ --with-boost-libdir="${ESYSROOT}"/usr/$(get_libdir)
)
if use qt5 ; then
@@ -114,5 +113,6 @@ src_install() {
DESTDIR="${D}" rake -j$(makeopts_jobs) install || die
einstalldocs
+ dodoc NEWS.md
doman doc/man/*.1
}
generated by cgit v1.2.3 (git 2.25.1) at 2024-06-08 06:45:50 +0000