summaryrefslogtreecommitdiff
path: root/media-libs
diff options
context:
space:
mode:
Diffstat (limited to 'media-libs')
-rw-r--r--media-libs/Manifest.gzbin67884 -> 68041 bytes
-rw-r--r--media-libs/gegl/Manifest2
-rw-r--r--media-libs/gegl/gegl-0.4.44.ebuild167
-rw-r--r--media-libs/openpgl/Manifest3
-rw-r--r--media-libs/openpgl/metadata.xml24
-rw-r--r--media-libs/openpgl/openpgl-0.5.0.ebuild37
6 files changed, 233 insertions, 0 deletions
diff --git a/media-libs/Manifest.gz b/media-libs/Manifest.gz
index c00a2a85fab3..ee04694c1562 100644
--- a/media-libs/Manifest.gz
+++ b/media-libs/Manifest.gz
Binary files differ
diff --git a/media-libs/gegl/Manifest b/media-libs/gegl/Manifest
index 27eca50a86f3..dee25e71fb97 100644
--- a/media-libs/gegl/Manifest
+++ b/media-libs/gegl/Manifest
@@ -2,7 +2,9 @@ AUX gegl-0.4.40-libraw-0.21.patch 936 BLAKE2B af0030e4d069f75751cbe7d9eef2e2ea4b
AUX gegl-0.4.40-strict-prototypes.patch 2555 BLAKE2B a377756270ea1cae19a5d890305c1075144389937294c23ec0cff6454742551b6e3bba72bce97d429c39f56517451597a564a19805d2bc19fc08d675c2a9e558 SHA512 8e8e223414bbf8499b622213ac73bb4566cb6d1b4d982eb63785a79a45038392b36c30cb328a6e89ae218d40813479b0b7fbba6dd980f050055990832e51b2fd
DIST gegl-0.4.40.tar.xz 5784744 BLAKE2B c4466a76ec4f7939161e9ead6980b8a701f3fc459c40c3de3e09caa688aae12fb1f4a9979ca82e95011437f229532ba07012590d00aeb97b610b69968faa454f SHA512 99ace5f1b916e56f31483b60a38f885d0e09652c834122390bba4439d9bb1a137d84770e1518187330c44f3491e53393cfb8802ba9ede20658e1c8122e798888
DIST gegl-0.4.42.tar.xz 5787100 BLAKE2B 6ae3ec98e72b1057b9d84551f56b675edb511994a73979bfccf559e24d3d636ba915aab10d3b3a1b38989d69c63692d3f312c621819700332c8cc1a4b3e86875 SHA512 29ccd93faa6127b6a9b1180eeba47f1b6f9bc06da8a5c9d68315d7474b77ff19d1084a6f4e7b218666b355329b17bc562f5906a334aa2baf93840d7caa0adf57
+DIST gegl-0.4.44.tar.xz 5791844 BLAKE2B dbbdca0ff9985025f528fe298df32672069c09dd87e22ab70330f078ca7fc7efb8b78f8f9077bb559eb61c790c5ab50c53853a1032fe00fbea7080d140baa28c SHA512 4dd3fad0c5e391fc1ac3784d4365ffdc483d37b90a24a29eaa632dd337971674999b2e0f8facf255d86852a3899cc51f4d27f9875ab5849f8b38d9ed5bb7413a
EBUILD gegl-0.4.40-r1.ebuild 5056 BLAKE2B 70db81c565564ce7330f36d1435b7abd2c368ac5e967cdb684784537e1752cc2f95453826fdb30d01d93bec5f5a5a94a1fe78cf8e1c57579aef56326d20d0f2d SHA512 3ce0f2aac7baaa4d654d7eaef917ff6c94fa2a4eca16ace26be6423c23facefce5de1e14e82496b9b32c20d12574aab62a3093d328b04308746117b6832b3fcf
EBUILD gegl-0.4.42-r1.ebuild 5035 BLAKE2B a2140fa970486877e094de08d320f3efafbcb056d60832243744164b4fd2940ed7818c636d9e28249df40437cd2ad4a9a7c6b1351def2f9a8a3de3f8f6f6703a SHA512 49dfa07c3075c5cea33b36df23dcfd5063b5b912072e5ec3034ac44178305ad9ae42767e106b162c7fc0dc23d610abc2ff8ac6bdea49452cfa4e3c3f3b528fba
+EBUILD gegl-0.4.44.ebuild 4970 BLAKE2B cab445e66e3cfba67da468530a5e73cb2e853e60d230391504813dca9d615fddc4cb74ce84103619ad3f77935d18aafe30c64f7ee8c1c5392463b48ba1aa5895 SHA512 96fc9c538a649ed11db45d7ae4ccbe0024a405660b0f302073a9f930c50ebac3d10a89a7ab85f393778512bcb4d162eb9d3d2a17fa1c3b9d5c1d4484debe8fd6
EBUILD gegl-9999.ebuild 4749 BLAKE2B f9c275c0ce0223df7af16be825474e687a6447dc78d19342a3cc90504a76aa3c98d65cf9609e6628e7d9fd650c99251be19c283c2f1fbe7be84571420a7096b6 SHA512 a7f6d89d928ce2e7850bbac75bc4af7d7c7d9e2a06724477c83281a4310418782ea340ec1caf9b7d904bc4dbbc3cae8e759a1031344cf7e5c1ec64801c7e69b8
MISC metadata.xml 761 BLAKE2B fa74f6ff5ae13c05793505d0a27b7bc8587748ad356fa4f3ec5b48bd2919c6197788ab02bdc02fbdbdfe2f376d93222b600e30915e50f4ee4643e973ce054d86 SHA512 8cf93e9c5130a017bb864144e88cd2a4f2eff17b5543514a3ca84066b90e394dda6ee64a5e49d8db3b48eb905df5eef815f3b2689bc2be9772a01dcd2cecad30
diff --git a/media-libs/gegl/gegl-0.4.44.ebuild b/media-libs/gegl/gegl-0.4.44.ebuild
new file mode 100644
index 000000000000..b03263aeac7c
--- /dev/null
+++ b/media-libs/gegl/gegl-0.4.44.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+# vala and introspection support is broken, bug #468208
+VALA_USE_DEPEND=vapigen
+
+inherit flag-o-matic meson optfeature python-any-r1 toolchain-funcs vala
+
+if [[ ${PV} == *9999* ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gegl.git"
+ SRC_URI=""
+else
+ SRC_URI="https://download.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="https://gegl.org/"
+
+LICENSE="|| ( GPL-3+ LGPL-3 )"
+SLOT="0.4"
+
+IUSE="cairo debug ffmpeg introspection lcms lensfun openexr openmp pdf raw sdl sdl2 svg test tiff umfpack vala v4l webp"
+REQUIRED_USE="
+ svg? ( cairo )
+ test? ( introspection )
+ vala? ( introspection )
+"
+
+RESTRICT="!test? ( test )"
+
+# NOTE: Even current libav 11.4 does not have AV_CODEC_CAP_VARIABLE_FRAME_SIZE
+# so there is no chance to support libav right now (Gentoo bug #567638)
+# If it returns, please check prior GEGL ebuilds for how libav was integrated. Thanks!
+RDEPEND="
+ >=dev-libs/glib-2.68.2:2
+ >=dev-libs/json-glib-1.2.6
+ >=media-libs/babl-0.1.98[introspection?,lcms?,vala?]
+ media-libs/libjpeg-turbo
+ media-libs/libnsgif
+ >=media-libs/libpng-1.6.0:0=
+ >=sys-libs/zlib-1.2.0
+ >=x11-libs/gdk-pixbuf-2.32:2
+ >=x11-libs/pango-1.38.0
+ cairo? ( >=x11-libs/cairo-1.12.2 )
+ ffmpeg? ( media-video/ffmpeg:0= )
+ introspection? ( >=dev-libs/gobject-introspection-1.32:= )
+ lcms? ( >=media-libs/lcms-2.8:2 )
+ lensfun? ( >=media-libs/lensfun-0.2.5 )
+ openexr? ( >=media-libs/openexr-1.6.1:= )
+ pdf? ( >=app-text/poppler-0.71.0[cairo] )
+ raw? ( >=media-libs/libraw-0.15.4:0= )
+ sdl? ( >=media-libs/libsdl-1.2.0 )
+ sdl2? ( >=media-libs/libsdl2-2.0.20 )
+ svg? ( >=gnome-base/librsvg-2.40.6:2 )
+ tiff? ( >=media-libs/tiff-4:= )
+ umfpack? ( sci-libs/umfpack )
+ v4l? ( >=media-libs/libv4l-1.0.1 )
+ webp? ( >=media-libs/libwebp-0.5.0:= )
+"
+DEPEND="${RDEPEND}
+ x11-base/xorg-proto"
+BDEPEND="
+ ${PYTHON_DEPS}
+ dev-lang/perl
+ >=dev-util/gtk-doc-am-1
+ >=sys-devel/gettext-0.19.8
+ >=sys-devel/libtool-2.2
+ virtual/pkgconfig
+ test? ( $(python_gen_any_dep '>=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]') )
+ vala? ( $(vala_depend) )
+"
+
+DOCS=( AUTHORS docs/ChangeLog docs/NEWS.adoc )
+
+pkg_pretend() {
+ [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+ [[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+ python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+ use test || return 0
+ python_has_version -b ">=dev-python/pygobject-3.2:3[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+ default
+ # patch executables suffix
+ sed -i -e "s/'gegl'/'gegl-0.4'/" bin/meson.build || die
+ sed -i -e "s/'gegl-imgcmp'/'gegl-imgcmp-0.4'/" tools/meson.build || die
+ sed -i -e "s/gegl-imgcmp/gegl-imgcmp-0.4/" tests/simple/test-exp-combine.sh || die
+ # skip UNEXPECTED PASSED 'matting-levin' test
+ sed -i -e "s/composition_tests += 'matting-levin'//" \
+ -e "s/composition_tests_fail += 'matting-levin'//" tests/compositions/meson.build || die
+
+ # don't require Apple's OpenCL on versions of OSX that don't have it
+ if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -le 9 ]] ; then
+ sed -i -e 's/#ifdef __APPLE__/#if 0/' gegl/opencl/* || die
+ fi
+
+ # fix 'build'headers from *.cl on gentoo-hardened, bug 739816
+ pushd "${S}/opencl/" || die
+ for file in *.cl; do
+ if [[ -f ${file} ]]; then
+ "${EPYTHON}" cltostring.py "${file}" || die
+ fi
+ done
+ popd || die
+}
+
+src_configure() {
+ # Bug #859901
+ filter-lto
+
+ use vala && vala_setup
+
+ local emesonargs=(
+ # - Disable documentation as the generating is bit automagic
+ # if anyone wants to work on it just create bug with patch
+ -Ddocs=false
+ -Dexiv2=disabled
+ -Dgdk-pixbuf=enabled
+ -Djasper=disabled
+ # - libspiro: not in portage main tree
+ -Dlibspiro=disabled
+ -Dlua=disabled
+ -Dmrg=disabled
+ -Dpango=enabled
+ # - Parameter -Dworkshop=false disables any use of Lua, effectivly
+ -Dworkshop=false
+ $(meson_feature cairo)
+ $(meson_feature cairo pangocairo)
+ $(meson_feature ffmpeg libav)
+ $(meson_feature lcms)
+ $(meson_feature lensfun)
+ $(meson_feature openexr)
+ $(meson_feature openmp)
+ $(meson_feature pdf poppler)
+ $(meson_feature raw libraw)
+ $(meson_feature sdl sdl1)
+ $(meson_feature sdl2 sdl2)
+ $(meson_feature svg librsvg)
+ $(meson_feature test pygobject)
+ $(meson_feature tiff libtiff)
+ $(meson_feature umfpack)
+ # - v4l support does not work with our media-libs/libv4l-0.8.9,
+ # upstream bug at https://bugzilla.gnome.org/show_bug.cgi?id=654675
+ $(meson_feature v4l libv4l)
+ $(meson_feature v4l libv4l2)
+ $(meson_feature vala vapigen)
+ $(meson_feature webp)
+ $(meson_use introspection)
+ )
+ meson_src_configure
+}
+
+pkg_postinst() {
+ optfeature "'Show Image Graph' under GIMP[debug] menu 'File - Debug'" media-gfx/graphviz
+}
diff --git a/media-libs/openpgl/Manifest b/media-libs/openpgl/Manifest
new file mode 100644
index 000000000000..5d52e2efb6ab
--- /dev/null
+++ b/media-libs/openpgl/Manifest
@@ -0,0 +1,3 @@
+DIST openpgl-0.5.0.tar.gz 10767365 BLAKE2B 051b26c17300506dd20989ba9dc1aa83b0baf77c5f24650c74518ae56081b5a0ecca88c13d5d79a71cb0b6fa4a5b4841ee03e5223ec91ab16bb5655f2e52a9d7 SHA512 9b992ffa17ad6f9fcde48add5d9cc1e58be2daacd40478fb1babe0741a6c7a64f12f36c9c1f7d5ec6f79cdd847c082d39e03e58cfd9af1a903adca56f1ac19e1
+EBUILD openpgl-0.5.0.ebuild 872 BLAKE2B c9283be19c0c9bfcde71de6305f4d32df2d28aacc12c5843155f53b81f494d08181fcf137d87d2b7dcd3a9138f6e4f61b0423e6c2c2351f95345ef731ccf0efe SHA512 21e303ea511abadaee500985f2575b2e803147fb19f1028f4afe597494896407ff06e7a71aa56c727fd3786322cf99a582e3db2f365414845f557c07fc5ae966
+MISC metadata.xml 1011 BLAKE2B c88245ac6d49bf09e2a96754713dcf088ec1ba4700713d2551a8af4f9c509553edbde8e9775fb1bc410b2eec742df26527b07d5cd36194ae5a2b4c5c018b51b1 SHA512 ff6c48d3db9dfd2737410f5d689d08fcb49a062bc291eb0e5442851037723a701629c13d44929b6812df5098adda7695b1edbd1bae9ed3cca63cf04b710cfdf2
diff --git a/media-libs/openpgl/metadata.xml b/media-libs/openpgl/metadata.xml
new file mode 100644
index 000000000000..362878695f7a
--- /dev/null
+++ b/media-libs/openpgl/metadata.xml
@@ -0,0 +1,24 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person" proxied="yes">
+ <email>darkdefende@gmail.com</email>
+ <name>Sebastian Parborg</name>
+ </maintainer>
+ <maintainer type="project" proxied="proxy">
+ <email>proxy-maint@gentoo.org</email>
+ <name>Proxy Maintainers</name>
+ </maintainer>
+ <longdescription>
+ The Intel® Open Path Guiding Library (Intel® Open PGL) implements a set of
+ representations and training algorithms needed to integrate path guiding
+ into a renderer. Open PGL offers implementations of current state-of-the-art
+ path guiding methods, which increase the sampling quality and, therefore,
+ the efficiency of a renderer. The goal of Open PGL is to provide
+ implementations that are well tested and robust enough to be used in a
+ production environment.
+ </longdescription>
+ <upstream>
+ <remote-id type="github">OpenPathGuidingLibrary/openpgl</remote-id>
+ </upstream>
+</pkgmetadata>
diff --git a/media-libs/openpgl/openpgl-0.5.0.ebuild b/media-libs/openpgl/openpgl-0.5.0.ebuild
new file mode 100644
index 000000000000..81276940fbc2
--- /dev/null
+++ b/media-libs/openpgl/openpgl-0.5.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Intel Open Path Guiding Library"
+HOMEPAGE="https://github.com/OpenPathGuidingLibrary/openpgl"
+SRC_URI="https://github.com/OpenPathGuidingLibrary/openpgl/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+X86_CPU_FLAGS=( sse4_2 avx2 avx512dq )
+CPU_FLAGS=( ${X86_CPU_FLAGS[@]/#/cpu_flags_x86_} )
+IUSE="${CPU_FLAGS[@]%:*} debug"
+
+RDEPEND="
+ media-libs/embree
+ dev-cpp/tbb:=
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+ local mycmakeargs=(
+ -DOPENPGL_ISA_AVX2=$(usex cpu_flags_x86_avx2)
+ -DOPENPGL_ISA_AVX512=$(usex cpu_flags_x86_avx512dq)
+ -DOPENPGL_ISA_SSE4=$(usex cpu_flags_x86_sse4_2)
+ )
+
+ # Disable asserts
+ append-cppflags $(usex debug '' '-DNDEBUG')
+
+ cmake_src_configure
+}
generated by cgit v1.2.3 (git 2.25.1) at 2024-07-01 03:45:06 +0000