1 files changed, 64 insertions, 0 deletions
diff --git a/media-libs/sratom/sratom-0.6.10.ebuild b/media-libs/sratom/sratom-0.6.10.ebuild
new file mode 100644
index 000000000000..f7864ab3044d
--- /dev/null
+++ b/media-libs/sratom/sratom-0.6.10.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE='threads(+)'
+inherit python-any-r1 waf-utils multilib-build multilib-minimal
+
+DESCRIPTION="Library for serialising LV2 atoms to/from RDF, particularly the Turtle syntax"
+HOMEPAGE="http://drobilla.net/software/sratom/"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~sparc x86"
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-python/sphinx
+		dev-python/sphinx_lv2_theme
+)
+"
+RDEPEND="
+	dev-libs/serd
+	dev-libs/sord
+	media-libs/lv2
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+"
+DOCS=( "NEWS" "README.md" )
+
+src_prepare() {
+	sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		--docdir=/usr/share/doc/${PF} \
+		$(multilib_native_usex doc --docs "") \
+		$(usex test --test "") \
+		$(usex static-libs --static "")
+}
+
+multilib_src_test() {
+	./waf test || die
+}
+
+multilib_src_compile() {
+	waf-utils_src_compile
+	default
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+	default
+}