1 files changed, 82 insertions, 0 deletions
diff --git a/media-libs/libmygpo-qt/libmygpo-qt-9999.ebuild b/media-libs/libmygpo-qt/libmygpo-qt-9999.ebuild
new file mode 100644
index 000000000000..6a6e0b5b0b20
--- /dev/null
+++ b/media-libs/libmygpo-qt/libmygpo-qt-9999.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils multibuild
+
+DESCRIPTION="Qt/C++ library wrapping the gpodder.net webservice"
+HOMEPAGE="http://wiki.gpodder.org/wiki/Libmygpo-qt"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/gpodder/libmygpo-qt.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/gpodder/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="+qt4 qt5 test"
+
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	qt4? (
+		>=dev-libs/qjson-0.5[qt4(+)]
+		dev-qt/qtcore:4
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtnetwork:5
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? (
+		qt4? ( dev-qt/qttest:4 )
+		qt5? ( dev-qt/qttest:5 )
+	)
+"
+
+DOCS=( AUTHORS README )
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt4) $(usev qt5) )
+	if use qt5; then
+		ewarn "Please note that Qt5 support is still experimental."
+		ewarn "If you find anything to not work with Qt5, please report a bug."
+	fi
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DMYGPO_BUILD_TESTS=$(usex test)
+		)
+
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=(-DBUILD_WITH_QT4=ON)
+		fi
+
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			mycmakeargs+=(-DBUILD_WITH_QT4=OFF)
+		fi
+
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_test() {
+	multibuild_foreach_variant cmake-utils_src_test
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+}