1 files changed, 41 insertions, 0 deletions
diff --git a/media-libs/kcolorpicker/kcolorpicker-0.3.1.ebuild b/media-libs/kcolorpicker/kcolorpicker-0.3.1.ebuild
new file mode 100644
index 000000000000..ba108063e02c
--- /dev/null
+++ b/media-libs/kcolorpicker/kcolorpicker-0.3.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PN=kColorPicker
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Qt based color picker with popup menu"
+HOMEPAGE="https://github.com/ksnip/kColorPicker"
+SRC_URI="https://github.com/ksnip/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtbase:6[gui,widgets]
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qtbase:6 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_WITH_QT6=ON
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local -x QT_QPA_PLATFORM=offscreen
+	cmake_src_test
+}