1 files changed, 48 insertions, 0 deletions
diff --git a/media-gfx/potrace/potrace-1.16-r1.ebuild b/media-gfx/potrace/potrace-1.16-r1.ebuild
new file mode 100644
index 000000000000..ac9fe7c8ddb2
--- /dev/null
+++ b/media-gfx/potrace/potrace-1.16-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Transforming bitmaps into vector graphics"
+HOMEPAGE="https://potrace.sourceforge.net/"
+SRC_URI="https://potrace.sourceforge.net/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="metric"
+
+RDEPEND="sys-libs/zlib:="
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.16-lto.patch
+)
+
+src_prepare() {
+	default
+
+	# Needed for lto patch
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC # bug 610098
+	local myeconfargs=(
+		--disable-static
+		--enable-zlib
+		--with-libpotrace
+		$(use_enable metric a4)
+		$(use_enable metric)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}