1 files changed, 70 insertions, 0 deletions
diff --git a/media-gfx/nomacs/nomacs-3.12.ebuild b/media-gfx/nomacs/nomacs-3.12.ebuild
new file mode 100644
index 000000000000..cd9011453890
--- /dev/null
+++ b/media-gfx/nomacs/nomacs-3.12.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="Qt-based image viewer"
+HOMEPAGE="https://nomacs.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+IUSE="heif +jpeg +opencv raw tiff zip"
+
+REQUIRED_USE="
+	raw? ( opencv )
+	tiff? ( opencv )
+"
+
+RDEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[jpeg?]
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-gfx/exiv2:=
+	heif? ( media-libs/libheif:= )
+	opencv? ( >=media-libs/opencv-3.4:= )
+	raw? ( media-libs/libraw:= )
+	tiff? (
+		dev-qt/qtimageformats:5
+		media-libs/tiff:0
+	)
+	zip? ( dev-libs/quazip[qt5(+)] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${P}/ImageLounge"
+
+DOCS=( src/changelog.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CODE_COV=OFF
+		-DUSE_SYSTEM_QUAZIP=ON
+		-DENABLE_TRANSLATIONS=ON
+		-DENABLE_HEIF=$(usex heif)
+		-DENABLE_OPENCV=$(usex opencv)
+		-DENABLE_RAW=$(usex raw)
+		-DENABLE_TIFF=$(usex tiff)
+		-DENABLE_QUAZIP=$(usex zip)
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}