1 files changed, 69 insertions, 0 deletions
diff --git a/gui-libs/xdg-desktop-portal-wlr/xdg-desktop-portal-wlr-0.7.0-r2.ebuild b/gui-libs/xdg-desktop-portal-wlr/xdg-desktop-portal-wlr-0.7.0-r2.ebuild
new file mode 100644
index 000000000000..4d9cd474ecb2
--- /dev/null
+++ b/gui-libs/xdg-desktop-portal-wlr/xdg-desktop-portal-wlr-0.7.0-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="xdg-desktop-portal backend for wlroots"
+HOMEPAGE="https://github.com/emersion/xdg-desktop-portal-wlr"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/emersion/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/emersion/${PN}/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	>=media-video/pipewire-0.3.62:=
+	dev-libs/inih
+	dev-libs/wayland
+	media-libs/mesa
+	x11-libs/libdrm
+	|| (
+		systemd? ( >=sys-apps/systemd-237 )
+		elogind? ( >=sys-auth/elogind-237 )
+		sys-libs/basu
+	)
+"
+# mesa is needed for gbm dep (which it hards sets to 'on')
+RDEPEND="
+	${DEPEND}
+	sys-apps/xdg-desktop-portal
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.24
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-portal-config.patch
+)
+
+src_configure() {
+	local emesonargs=()
+
+	if use systemd; then
+		emesonargs+=(-Dsd-bus-provider=libsystemd)
+	elif use elogind; then
+		emesonargs+=(-Dsd-bus-provider=libelogind)
+	else
+		emesonargs+=(-Dsd-bus-provider=basu)
+	fi
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# bug #915702
+	insinto /usr/share/xdg-desktop-portal
+	doins "${WORKDIR}/${P}/contrib/wlroots-portals.conf"
+}