1 files changed, 0 insertions, 62 deletions
diff --git a/gnome-base/dconf/dconf-0.26.0-r1.ebuild b/gnome-base/dconf/dconf-0.26.0-r1.ebuild
deleted file mode 100644
index 1187976d9e36..000000000000
--- a/gnome-base/dconf/dconf-0.26.0-r1.ebuild
+++ /dev/null
@@ -1,62 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit gnome2 bash-completion-r1 virtualx
-
-DESCRIPTION="Simple low-level configuration system"
-HOMEPAGE="https://wiki.gnome.org/action/show/Projects/dconf"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~sh sparc x86 ~x86-fbsd ~arm-linux ~x86-linux"
-IUSE=""
-
-RDEPEND="
-	>=dev-libs/glib-2.44.0:2
-	sys-apps/dbus
-"
-DEPEND="${RDEPEND}
-	app-text/docbook-xml-dtd:4.2
-	app-text/docbook-xsl-stylesheets
-	dev-libs/libxslt
-	dev-util/gdbus-codegen
-	>=dev-util/gtk-doc-am-1.15
-	sys-devel/gettext
-	virtual/pkgconfig
-"
-
-src_configure() {
-	gnome2_src_configure \
-		--disable-gcov \
-		--enable-man \
-		VALAC=$(type -P true)
-}
-
-src_test() {
-	virtx emake check
-}
-
-src_install() {
-	gnome2_src_install
-
-	# GSettings backend may be one of: memory, gconf, dconf
-	# Only dconf is really considered functional by upstream
-	# must have it enabled over gconf if both are installed
-	echo 'CONFIG_PROTECT_MASK="/etc/dconf"' >> 51dconf
-	echo 'GSETTINGS_BACKEND="dconf"' >> 51dconf
-	doenvd 51dconf
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	# Kill existing dconf-service processes as recommended by upstream due to
-	# possible changes in the dconf private dbus API.
-	# dconf-service will be dbus-activated on next use.
-	pids=$(pgrep -x dconf-service)
-	if [[ $? == 0 ]]; then
-		ebegin "Stopping dconf-service; it will automatically restart on demand"
-		kill ${pids}
-		eend $?
-	fi
-}