1 files changed, 39 insertions, 0 deletions
diff --git a/games-strategy/maxr/maxr-0.2.9.ebuild b/games-strategy/maxr/maxr-0.2.9.ebuild
new file mode 100644
index 000000000000..624345a06b30
--- /dev/null
+++ b/games-strategy/maxr/maxr-0.2.9.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils desktop gnome2-utils
+
+DESCRIPTION="Mechanized Assault and Exploration Reloaded"
+HOMEPAGE="http://www.maxr.org/"
+SRC_URI="http://www.maxr.org/downloads/${P}.tar.gz"
+
+LICENSE="GPL-2 FDL-1.2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="dedicated"
+
+RDEPEND="media-libs/libsdl2[video]
+	media-libs/sdl2-mixer[vorbis]
+	media-libs/sdl2-net"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	mycmakeargs=(
+		-DMAXR_BUILD_DEDICATED_SERVER=$(usex dedicated)
+		-DCMAKE_BUILD_TYPE=Release
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	doicon -s 128 data/${PN}.png
+	make_desktop_entry ${PN} "Mechanized Assault and Exploration Reloaded"
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }