1 files changed, 51 insertions, 0 deletions
diff --git a/games-board/gtkboard/gtkboard-0.11_pre0-r1.ebuild b/games-board/gtkboard/gtkboard-0.11_pre0-r1.ebuild
new file mode 100644
index 000000000000..fe97dee177fa
--- /dev/null
+++ b/games-board/gtkboard/gtkboard-0.11_pre0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils
+
+MY_P=${P/_}
+DESCRIPTION="Board games system"
+HOMEPAGE="http://gtkboard.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome"
+
+RDEPEND="x11-libs/gtk+:2
+	media-libs/libsdl:0[sound]
+	media-libs/sdl-mixer[vorbis]
+	gnome? ( gnome-base/libgnomeui )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gcc41.patch
+	"${FILESDIR}"/${P}-gcc45.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e "/^LIBS/s:@LIBS@:@LIBS@ -lgmodule-2.0 -lm:" \
+		src/Makefile.in
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		--enable-gtk2 \
+		--enable-sdl \
+		$(use_enable gnome)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	doicon pixmaps/${PN}.png
+	make_desktop_entry ${PN} Gtkboard
+	dodoc AUTHORS ChangeLog TODO doc/index.html
+}