1 files changed, 59 insertions, 0 deletions
diff --git a/games-arcade/pacmanarena/pacmanarena-0.15-r2.ebuild b/games-arcade/pacmanarena/pacmanarena-0.15-r2.ebuild
new file mode 100644
index 000000000000..4b16585222e4
--- /dev/null
+++ b/games-arcade/pacmanarena/pacmanarena-0.15-r2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools desktop
+
+DESCRIPTION="3D Pacman clone with a few surprises. Rockets, bombs and explosions abound"
+HOMEPAGE="http://pacmanarena.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/pacman-arena-${PV}.tar.bz2
+	mirror://sourceforge/${PN}/pacman-data-0.0.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~x86"
+
+RDEPEND="
+	media-libs/libsdl[sound]
+	media-libs/sdl-mixer[vorbis]
+	media-libs/sdl-net
+	virtual/glu
+	virtual/opengl
+"
+DEPEND="${RDEPEND}"
+BDEPEND="app-arch/unzip"
+
+S="${WORKDIR}/pacman"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-underlink.patch
+	"${FILESDIR}"/${P}-fnocommon.patch
+)
+
+src_unpack() {
+	unpack pacman-arena-${PV}.tar.bz2
+	cd "${S}"
+	unpack pacman-data-0.0.zip
+}
+
+src_prepare() {
+	default
+	sed -i \
+		-e "/^CFLAGS/ s:pacman:${PN}:" \
+		-e '1i CC=@CC@' \
+		Makefile.in || die
+	sed -i \
+		-e '/CFLAGS/s:-g::' \
+		configure.ac || die
+	eautoreconf
+}
+
+src_install() {
+	newbin pacman ${PN}
+	insinto /usr/share/${PN}
+	doins -r gfx sfx
+	newicon gfx/pacman_arena1.tga ${PN}.tga
+	make_desktop_entry ${PN} "Pacman Arena" /usr/share/pixmaps/${PN}.tga
+	einstalldocs
+}