1 files changed, 45 insertions, 0 deletions
diff --git a/dev-util/spirv-tools/spirv-tools-2019.10_pre20191027-r1.ebuild b/dev-util/spirv-tools/spirv-tools-2019.10_pre20191027-r1.ebuild
new file mode 100644
index 000000000000..6949158877af
--- /dev/null
+++ b/dev-util/spirv-tools/spirv-tools-2019.10_pre20191027-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit cmake-multilib cmake-utils python-any-r1
+
+DESCRIPTION="Provides an API and commands for processing SPIR-V modules"
+HOMEPAGE="https://github.com/KhronosGroup/SPIRV-Tools"
+EGIT_COMMIT="ec12de9131244a076c34ddca2e8d7451288be7e1"
+SRC_URI="https://github.com/KhronosGroup/SPIRV-Tools/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+# Tests fail upon finding symbols that do not match a regular expression
+# in the generated library. Easily hit with non-standard compiler flags
+RESTRICT="test"
+
+COMMON_DEPEND=">=dev-util/spirv-headers-1.5.1"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND=""
+BDEPEND="${PYTHON_DEPS}
+	${COMMON_DEPEND}"
+
+PATCHES=( "${FILESDIR}/${P}-Respect-CMAKE_INSTALL_LIBDIR-in-installed-CMake-files.patch" )
+
+S="${WORKDIR}/SPIRV-Tools-${EGIT_COMMIT}"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		"-DSPIRV-Headers_SOURCE_DIR=/usr/"
+		"-DSPIRV_WERROR=OFF"
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+	echo "${EGIT_COMMIT}" > "${PN}-commit.h" || die
+	insinto /usr/include/"${PN}"
+	doins  "${PN}-commit.h"
+}