1 files changed, 38 insertions, 0 deletions
diff --git a/dev-util/smem/smem-1.5-r1.ebuild b/dev-util/smem/smem-1.5-r1.ebuild
new file mode 100644
index 000000000000..a910bb665c9d
--- /dev/null
+++ b/dev-util/smem/smem-1.5-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_COMMIT="2ab5040d5633"
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit eutils python-single-r1 toolchain-funcs
+
+DESCRIPTION="A tool that can give numerous reports on memory usage on Linux systems"
+HOMEPAGE="https://www.selenic.com/smem/"
+SRC_URI="https://selenic.com/repo/${PN}/archive/${EGIT_COMMIT}.tar.bz2 -> ${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}"
+BDEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+
+src_compile() {
+	"$(tc-getCC)" ${CFLAGS} ${LDFLAGS} -o smemcap smemcap.c || die
+}
+
+src_install() {
+	dobin smemcap
+	python_doexe smem
+
+	doman smem.8
+}
+
+pkg_postinst() {
+	optfeature "for chart generation." dev-python/matplotlib
+}