1 files changed, 54 insertions, 0 deletions
diff --git a/dev-util/rbtools/rbtools-4.1.ebuild b/dev-util/rbtools/rbtools-4.1.ebuild
new file mode 100644
index 000000000000..c0f335a6237d
--- /dev/null
+++ b/dev-util/rbtools/rbtools-4.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Command line tools for use with Review Board"
+HOMEPAGE="https://www.reviewboard.org/"
+SRC_URI="https://github.com/reviewboard/rbtools/archive/refs/tags/release-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/rbtools-release-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-python/certifi-2023.5.7[${PYTHON_USEDEP}]
+	>=dev-python/importlib-metadata-4.12[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	>=dev-python/pydiffx-1.1[${PYTHON_USEDEP}]
+	=dev-python/pydiffx-1.1*[${PYTHON_USEDEP}]
+	>=dev-python/six-1.8.0[${PYTHON_USEDEP}]
+	dev-python/texttable[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.3.0[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/kgb-6.1[${PYTHON_USEDEP}]
+		dev-python/pytest-env[${PYTHON_USEDEP}]
+		dev-vcs/git
+		dev-vcs/mercurial
+	)
+"
+
+DOCS=( AUTHORS NEWS README.md )
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Avoid tests requiring unpackaged test data
+	rm -f rbtools/clients/tests/test_scanning.py || die
+
+	# Avoid repository specific tests to avoid dependencies on them
+	rm -f rbtools/clients/tests/test_{cvs,git,mercurial,svn}.py || die
+}