summaryrefslogtreecommitdiff
path: root/dev-util/poke
diff options
context:
space:
mode:
Diffstat (limited to 'dev-util/poke')
-rw-r--r--dev-util/poke/Manifest5
-rw-r--r--dev-util/poke/files/50poke-gentoo.el9
-rw-r--r--dev-util/poke/metadata.xml1
-rw-r--r--dev-util/poke/poke-2.4-r1.ebuild123
-rw-r--r--dev-util/poke/poke-9999.ebuild116
5 files changed, 253 insertions, 1 deletions
diff --git a/dev-util/poke/Manifest b/dev-util/poke/Manifest
index 349154f7e7ad..da735c048931 100644
--- a/dev-util/poke/Manifest
+++ b/dev-util/poke/Manifest
@@ -1,5 +1,8 @@
+AUX 50poke-gentoo.el 334 BLAKE2B f5519ada4b710ea3c7aacdf716674b4a5d8b1af3d639b5de72f58cf974335ca49a27641c305c31fc34e07d88fedb959674d402355324b89fe955df73e418f302 SHA512 293ef7fbe66bbba71580173cebed9ba0bbe76f862e4ddc6ec78302724e7fc9eb159e40404bee46c32a30f472efeb7ed60d464b4324d0c8ca8cf147220a4d76ca
DIST poke-2.3.tar.gz 7369945 BLAKE2B fe9274099a9ddacf1f46b7cec1f98cc6c442b24f149efbf4320a74a270dc8bad7cf3f87df817c9968a13ece763573b36f0ec99699cb9c7742b7be9023a4fca39 SHA512 101ef0009676c02f72ffb4889a02c9a161f29f412685249c7166f69077b0cd1b19d940567ebb86894bacf2278a2e138354fd49456f12b05a4c1957f437ff1d86
DIST poke-2.4.tar.gz 7372092 BLAKE2B 64b8b22713bb581c30b624200c0a283a8de548895db2c21d83babbb18a93f3a8975dd7af752bd7ea856242f90035add249fbb62462ac632bec351598bcca0fe5 SHA512 6fa1097a5cbbd4171b6a390934c5648b4c382b8b8c8dd4955bba82cb57107f67e23b39f2df2081904a02f457e6c5b2d10baed710da3ed4b9b9eab3f4127e12bc
EBUILD poke-2.3.ebuild 919 BLAKE2B d5edcf4aca522c508b2f3b3116983dda26824b50d9390e498e37c3d67f43e9f5f62391501c0dd9b77769ed649d2e177e243f32067948751a8168b7dcf93ddeec SHA512 8c7a9c529e2f32b51c7cb79e2748abbd805420254f8f398a8cc7b35136b2a5a71a44ac40e04f869e97e58286815b6037bdcc94e51184625ee7773e895e515a14
+EBUILD poke-2.4-r1.ebuild 2427 BLAKE2B 4a3f75e14c67993dd55767dda65da2a9f9e5b7734385e79732f12232ebdba1f881c9376787e9e7b688e4cf4102a6045c750eaf7ea540301213d126a7271ee61a SHA512 0265badd46fe1da752494ffd769b060c3ebf575cdfdc38ea54b99163bf7b23792978fa5d849ee6bbceb4123f78381ab6946aa367baecf6edf880b28a22603713
EBUILD poke-2.4.ebuild 1430 BLAKE2B f61f4eb13bf0f5d47e50c1c60df5d4f4548b3dff9ac719b4108ce9daa4dcae7f577128979ca3deff6c4c6502bbfbdf8a8d1130246c60dc7f164c50cf9da7b84e SHA512 81f235a365d29b1935bc3d34b21c57b999c757da0b5ab58786332cdae8ccdd0193cf5ddba8d3263290a63647b10fdfd4ac077e27a454cae9587c4d9219150bcf
-MISC metadata.xml 674 BLAKE2B 49967bd2b2686b6fbc52e0793b3b6196911b1badbceb1828459e422f0bb5a4e8ad7cc9ab8c10fe87c81040305a9a58ce8f0ddf7d2db4a25861b3605f81bfa775 SHA512 4c7deb851048c0570c840240313d5a094bb6945d23ff8a51d5e7b154913d6527c1735092541bd67e84af13d54bfd2e780b6081fe67255df1766fea64d04e17de
+EBUILD poke-9999.ebuild 2148 BLAKE2B f309891c4c847ad63db7c6950043cc4e8c46c7b51aaf76b7db810dee7833a0dfc9d46f769d3675a7ceac732f0cced4fcfe066224dc7c547ff0ffbfc6680c2b5c SHA512 5da9208f367197dfd2f74b81b826f34d413d739c0449da31af2ebd57b7d9e7f3ebb1c069ba42193b7e9657667442a85fcfbf5ab24926961aeb50217f7d496f47
+MISC metadata.xml 775 BLAKE2B 7b6c458435c2c0e2e22d853d6948b5cb1084aca3fda16d6e5a06968ff2687063acd48ec0f2d2e54cb7359791e86da9b8a9deeec7375ac10a936e2c03298081f1 SHA512 a0704750e4adc983cb5af00df0630491f8f47c0638d3c430e3e791b248790255dab29b3e4738efffbd408b5c4ec4253674e0da9658985480c494da2c7e05088c
diff --git a/dev-util/poke/files/50poke-gentoo.el b/dev-util/poke/files/50poke-gentoo.el
new file mode 100644
index 000000000000..5a173875dbcd
--- /dev/null
+++ b/dev-util/poke/files/50poke-gentoo.el
@@ -0,0 +1,9 @@
+;;; poke site-lisp configuration
+
+(autoload 'poke-ras-mode "poke-ras-mode"
+ "Major mode for writing poke RAS programs." t)
+(autoload 'poke-map-mode "poke-map-mode"
+ "Major mode for writing poke map-files." t)
+
+(add-to-list 'auto-mode-alist '(".*\\.pks" . poke-ras-mode))
+(add-to-list 'auto-mode-alist '(".*\\.map" . poke-map-mode))
diff --git a/dev-util/poke/metadata.xml b/dev-util/poke/metadata.xml
index 16899f52a82c..87e485e63e50 100644
--- a/dev-util/poke/metadata.xml
+++ b/dev-util/poke/metadata.xml
@@ -12,6 +12,7 @@
<use>
<flag name="machine-interface">Enable machine-interface protocol using <pkg>dev-libs/json-c</pkg></flag>
<flag name="pvm-profiling">Enable profiling in the PVM</flag>
+ <flag name="nbd">Enable poking at networked block devices via <pkg>sys-libs/libnbd</pkg>.</flag>
</use>
<upstream>
<remote-id type="savannah">poke</remote-id>
diff --git a/dev-util/poke/poke-2.4-r1.ebuild b/dev-util/poke/poke-2.4-r1.ebuild
new file mode 100644
index 000000000000..c903cab9b818
--- /dev/null
+++ b/dev-util/poke/poke-2.4-r1.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp-common flag-o-matic
+
+DESCRIPTION="Extensible editor for structured binary data"
+HOMEPAGE="https://www.jemarch.net/poke"
+
+if [[ ${PV} == 9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://git.savannah.gnu.org/git/poke.git"
+ REGEN_BDEPEND="
+ >=sys-devel/autoconf-2.62
+ >=sys-devel/automake-2.16
+ sys-apps/gawk
+ sys-apps/help2man
+ sys-apps/texinfo
+ sys-devel/bison
+ sys-devel/flex
+ "
+else
+ SRC_URI="mirror://gnu/poke/${P}.tar.gz"
+ KEYWORDS="~amd64"
+ REGEN_BDEPEND=""
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="emacs pvm-profiling nbd nls test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-libs/boehm-gc:=
+ dev-libs/libatomic_ops
+ sys-devel/gettext
+ sys-libs/readline:=
+ emacs? ( >=app-editors/emacs-23.1:* )
+ nbd? ( sys-libs/libnbd )
+"
+DEPEND="
+ ${RDEPEND}
+ test? ( nbd? ( sys-libs/libnbd[uri-support] ) )
+"
+BDEPEND="
+ ${REGEN_BDEPEND}
+ virtual/pkgconfig
+ emacs? ( >=app-editors/emacs-23.1:* )
+ test? (
+ dev-util/dejagnu
+ nbd? ( sys-block/nbdkit )
+ )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_setup() {
+ use emacs && elisp-check-emacs-version
+}
+
+src_prepare() {
+ default
+
+ if [[ ${PV} == 9999 ]]; then
+ ./bootstrap || die
+ fi
+}
+
+src_configure() {
+ # See bug 858461.
+ # Upstream support might happen one day. For context, only one file needs
+ # LTO to be disabled (since it's an autogenerated bytecode interpreter),
+ # others do not. The build system will handle this at some point in the
+ # future. Until then, just filter out LTO.
+ filter-lto
+
+ # NB --disable-{gui,mi}:
+ # These (AFAICT) have no consumers in Gentoo, and should not get any,
+ # preferably. They are slated for removal with Poke 3 (should happen
+ # towards the end of the year, possibly), so they should not be relied
+ # upon.
+ local myconf=(
+ --with-lispdir="${EPREFIX}/${SITELISP}/${PN}"
+ --enable-hserver
+ --disable-gui
+ --disable-mi
+ $(use_enable nbd libnbd)
+ $(use_enable pvm-profiling)
+ $(use_enable nls)
+ )
+
+ econf "${myconf[@]}"
+}
+
+src_compile() {
+ default
+
+ if use emacs; then
+ cd etc || die
+ elisp-compile *.el
+ fi
+}
+
+src_install() {
+ default
+
+ if use emacs; then
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ cd etc || die
+ elisp-install "${PN}" *.el *.elc
+ fi
+ find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
diff --git a/dev-util/poke/poke-9999.ebuild b/dev-util/poke/poke-9999.ebuild
new file mode 100644
index 000000000000..c50ed72d70ea
--- /dev/null
+++ b/dev-util/poke/poke-9999.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp-common flag-o-matic
+
+DESCRIPTION="Extensible editor for structured binary data"
+HOMEPAGE="https://www.jemarch.net/poke"
+
+if [[ ${PV} == 9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://git.savannah.gnu.org/git/poke.git"
+ REGEN_BDEPEND="
+ >=sys-devel/autoconf-2.62
+ >=sys-devel/automake-2.16
+ sys-apps/gawk
+ sys-apps/help2man
+ sys-apps/texinfo
+ sys-devel/bison
+ sys-devel/flex
+ "
+else
+ SRC_URI="mirror://gnu/poke/${P}.tar.gz"
+ KEYWORDS="~amd64"
+ REGEN_BDEPEND=""
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="emacs pvm-profiling nbd nls test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-libs/boehm-gc:=
+ dev-libs/libatomic_ops
+ sys-devel/gettext
+ sys-libs/readline:=
+ emacs? ( >=app-editors/emacs-23.1:* )
+ nbd? ( sys-libs/libnbd )
+"
+DEPEND="
+ ${RDEPEND}
+ test? ( nbd? ( sys-libs/libnbd[uri-support] ) )
+"
+BDEPEND="
+ ${REGEN_BDEPEND}
+ virtual/pkgconfig
+ emacs? ( >=app-editors/emacs-23.1:* )
+ test? (
+ dev-util/dejagnu
+ nbd? ( sys-block/nbdkit )
+ )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+pkg_setup() {
+ use emacs && elisp-check-emacs-version
+}
+
+src_prepare() {
+ default
+
+ if [[ ${PV} == 9999 ]]; then
+ ./bootstrap || die
+ fi
+}
+
+src_configure() {
+ # See bug 858461.
+ # Upstream support might happen one day. For context, only one file needs
+ # LTO to be disabled (since it's an autogenerated bytecode interpreter),
+ # others do not. The build system will handle this at some point in the
+ # future. Until then, just filter out LTO.
+ filter-lto
+
+ local myconf=(
+ --with-lispdir="${EPREFIX}/${SITELISP}/${PN}"
+ --enable-hserver
+ $(use_enable nbd libnbd)
+ $(use_enable pvm-profiling)
+ $(use_enable nls)
+ )
+
+ econf "${myconf[@]}"
+}
+
+src_compile() {
+ default
+
+ if use emacs; then
+ cd etc || die
+ elisp-compile *.el
+ fi
+}
+
+src_install() {
+ default
+
+ if use emacs; then
+ elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+ cd etc || die
+ elisp-install "${PN}" *.el *.elc
+ fi
+ find "${ED}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+ use emacs && elisp-site-regen
+}
generated by cgit v1.2.3 (git 2.25.1) at 2024-08-10 14:05:28 +0000