2 files changed, 97 insertions, 0 deletions
diff --git a/dev-util/distro-info/Manifest b/dev-util/distro-info/Manifest
index e2f58f1c2c55..7084b5128b3b 100644
--- a/dev-util/distro-info/Manifest
+++ b/dev-util/distro-info/Manifest
@@ -1,3 +1,5 @@
 DIST distro-info_0.14.tar.xz 26460 BLAKE2B eb34e31514f7acfd283ae9405132884ccae31b77d6cf7af3a8a341ac349d589cbd5d7828e763911fc490d6504edae4c90551b3d3cc3518eec1f47ab1dcc6ac60 SHA512 aa0055f21523e30fc7e9c94c92f87cbd05fc5d082ddc109d092e94dabafac7533ced984197797252eb698232b3d8f512b3c345ed6abef0ae074bf2770224955e
+DIST distro-info_0.22.tar.xz 29104 BLAKE2B 88eab833ea34de9e62f858e1fb9acfb94efb60114d2213b8bbb77a440c114dbac70a1707d1469113c1a98ea94d953ffa36480c132c294fd8e22b816a444b25e1 SHA512 b9d97e469b9173651c1816f39cc2315622b46f1579cbaba29c417a51417425e90a45283e83c7efee35db78621df08997f5395c8c1b0259f69e5cd91dee65793f
 EBUILD distro-info-0.14.ebuild 1915 BLAKE2B c9e3756cc5fddefb9323b86d37bec849dfb9009469001d8993280096115d33499a166999ee5ff2fed1c6002e8483638eb53fa7bcc17a81ac3d7b8faba60f7a64 SHA512 826420545318624a6d296944a2f51742e9151a0c49b9e9b69a969b8d63cf610fb45a142cb28bc3030e0398d8c11de0fbd065440153b0fbbeecaaba93c4543420
+EBUILD distro-info-0.22.ebuild 1949 BLAKE2B 0eb878daef459b89a2e048ba5bac2ae319eea1bb0bda08c68aed32abbb54a4dc8bd4e213cb14cad496fb00db5fe838369114d3743968123f0d7c6630765088ee SHA512 6d6825064119cb8a1f1fd476356fb7f44a8112858f57fbbd9d916bca91c1b9c7ce3cc0f18b8fcbf9e870537fa0d99c5a0ec19b376c5026e4afd932e539f9a5c9
 MISC metadata.xml 367 BLAKE2B 867a3664c5bbd444d69af80af19994e07e3810349258e85c2afd0c838cb140aa3f3342ee1aa5e6862d1fd5130e7e09c1f9f30443827fe7df705f4273694c0784 SHA512 3eb0be47e7eb6bfb6d8eecee66a25183da436c38272e226e7819c8748774f3aae620eab7227414cb862734d4baf8fa060290c1b2371233141abcffd7b489c7b8
diff --git a/dev-util/distro-info/distro-info-0.22.ebuild b/dev-util/distro-info/distro-info-0.22.ebuild
new file mode 100644
index 000000000000..5eb8469e6df8
--- /dev/null
+++ b/dev-util/distro-info/distro-info-0.22.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+DISTUTILS_OPTIONAL=true
+
+inherit distutils-r1
+
+DESCRIPTION="Provides information about the Debian distributions' releases"
+HOMEPAGE="https://debian.org"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="python test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="dev-lang/perl:=
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${COMMON_DEPEND}
+	python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+	test? (
+		dev-util/shunit2
+		dev-python/pylint[${PYTHON_USEDEP}]
+	)"
+RDEPEND="${COMMON_DEPEND}
+	dev-util/distro-info-data"
+
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	default
+
+	# 1. Gentoo do not provides dpkg vendor information
+	# 2. Strip *FLAGS
+	# 3. Strip predefined CFLAGS
+	# 4. Point to correct perl's vendorlib
+	# 5. Remove python tests - python eclass will be used instead
+	sed -e "/cd python && python/d" \
+		-e "/VENDOR/d" \
+		-e "/dpkg-buildflags/d" \
+		-e "s/-g -O2//g" \
+		-e "s:\$(PREFIX)/share/perl5/Debian:\$(PERL_VENDORLIB)/Debian:g" \
+		-e "/pyversions/d" \
+		-i "${S}"/Makefile || die
+}
+
+src_configure() {
+	default
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_configure
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_compile
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	emake PERL_VENDORLIB=$(perl -e 'require Config; print "$Config::Config{'vendorlib'}\n";') \
+		DESTDIR="${D}" install
+
+	if use python; then
+		pushd ./python > /dev/null || die
+		distutils-r1_src_install
+		popd > /dev/null || die
+	fi
+}
+
+src_test() {
+	TZ=UTC default
+
+	if use python; then
+		python_test() {
+			esetup.py test
+		}
+
+		pushd ./python > /dev/null || die
+		distutils-r1_src_test
+		popd > /dev/null || die
+	fi
+}