1 files changed, 65 insertions, 0 deletions
diff --git a/dev-util/clion/clion-1.2.4.143.1186.ebuild b/dev-util/clion/clion-1.2.4.143.1186.ebuild
new file mode 100644
index 000000000000..220bd4a563d8
--- /dev/null
+++ b/dev-util/clion/clion-1.2.4.143.1186.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils versionator
+
+SLOT="0"
+PV_STRING="$(get_version_component_range 4-6)"
+MY_PV="$(get_version_component_range 1-3)"
+
+KEYWORDS="~amd64 ~x86"
+SRC_URI="http://download.jetbrains.com/cpp/${PN}-${MY_PV}.tar.gz -> ${PN}-${PV_STRING}.tar.gz"
+DESCRIPTION="A complete toolset for C and C++ development"
+HOMEPAGE="http://www.jetbrains.com/clion"
+
+LICENSE="IDEA
+	|| ( IDEA_Academic IDEA_Classroom IDEA_OpenSource IDEA_Personal )"
+IUSE=""
+
+RDEPEND="${DEPEND}
+	sys-devel/gdb
+	dev-util/cmake"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+QA_PREBUILT="opt/${PN}-${MY_PV}/*"
+
+src_prepare() {
+	if ! use amd64; then
+		rm -r plugins/tfsIntegration/lib/native/linux/x86_64 || die
+	fi
+	if ! use arm; then
+		rm bin/fsnotifier-arm || die
+		rm -r plugins/tfsIntegration/lib/native/linux/arm || die
+	fi
+	if ! use ppc; then
+		rm -r plugins/tfsIntegration/lib/native/linux/ppc || die
+	fi
+	if ! use x86; then
+		rm -r plugins/tfsIntegration/lib/native/linux/x86 || die
+	fi
+
+	rm -r bin/cmake || die
+	rm license/CMake* || die
+	rm -r bin/gdb || die
+	rm license/GDB* || die
+
+	rm -r plugins/tfsIntegration/lib/native/solaris || die
+	rm -r plugins/tfsIntegration/lib/native/hpux || die
+}
+
+src_install() {
+	local dir="/opt/${PN}-${MY_PV}"
+
+	insinto "${dir}"
+	doins -r *
+	fperms 755 "${dir}"/bin/{clion.sh,fsnotifier{,64}}
+
+	make_wrapper "${PN}" "${dir}/bin/${PN}.sh"
+	newicon "bin/${PN}.svg" "${PN}.svg"
+	make_desktop_entry "${PN}" "clion" "${PN}" "Development;IDE;"
+
+	# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
+	mkdir -p "${D}/etc/sysctl.d/" || die
+	echo "fs.inotify.max_user_watches = 524288" > "${D}/etc/sysctl.d/30-idea-inotify-watches.conf" || die
+}