1 files changed, 51 insertions, 0 deletions
diff --git a/dev-qt/qtwayland/qtwayland-6.6.2-r1.ebuild b/dev-qt/qtwayland/qtwayland-6.6.2-r1.ebuild
new file mode 100644
index 000000000000..a9ab86107af3
--- /dev/null
+++ b/dev-qt/qtwayland/qtwayland-6.6.2-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qt6-build
+
+DESCRIPTION="Wayland platform plugin for Qt"
+
+if [[ ${QT6_BUILD_TYPE} == release ]]; then
+	KEYWORDS="amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+IUSE="accessibility compositor qml vulkan"
+
+RDEPEND="
+	dev-libs/wayland
+	~dev-qt/qtbase-${PV}:6[accessibility=,gui,opengl,vulkan=]
+	media-libs/libglvnd
+	x11-libs/libxkbcommon
+	compositor? (
+		qml? ( ~dev-qt/qtdeclarative-${PV}:6 )
+	)
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="dev-util/wayland-scanner"
+
+CMAKE_SKIP_TESTS=(
+	# segfaults for not-looked-into reasons, but not considered
+	# an issue given >=seatv5 exists since wayland-1.10 (2016)
+	tst_seatv4
+	# needs a compositor/opengl, skip the extra trouble
+	tst_surface
+	tst_xdgdecorationv1
+)
+
+PATCHES=(
+	"${FILESDIR}"/${P}-nvidia-threaded-gl.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package qml Qt6Quick)
+		$(qt_feature compositor wayland_server)
+	)
+
+	qt6-build_src_configure
+}