1 files changed, 50 insertions, 0 deletions
diff --git a/dev-python/zope-interface/zope-interface-4.5.0.ebuild b/dev-python/zope-interface/zope-interface-4.5.0.ebuild
new file mode 100644
index 000000000000..da0e81e1c162
--- /dev/null
+++ b/dev-python/zope-interface/zope-interface-4.5.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Interfaces for Python"
+HOMEPAGE="https://pypi.org/project/zope.interface/ https://github.com/zopefoundation/zope.interface"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+RDEPEND="
+	dev-python/namespace-zope[${PYTHON_USEDEP}]"
+
+DEPEND="
+	${RDEPEND}
+	>=dev-python/setuptools-33.1.1[${PYTHON_USEDEP}]
+	test? ( dev-python/zope-event[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}"
+		append-flags -fno-strict-aliasing
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# remove .pth files since dev-python/namespace-zope handles the ns
+	find "${D}" -name '*.pth' -delete || die
+}