1 files changed, 47 insertions, 0 deletions
diff --git a/dev-python/yapsy/yapsy-1.11.223-r2.ebuild b/dev-python/yapsy/yapsy-1.11.223-r2.ebuild
new file mode 100644
index 000000000000..62cd725684e6
--- /dev/null
+++ b/dev-python/yapsy/yapsy-1.11.223-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+MY_P="Yapsy-${PV}"
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="A fat-free DIY Python plugin management toolkit"
+HOMEPAGE="http://yapsy.sourceforge.net/"
+SRC_URI="mirror://sourceforge/yapsy/${MY_P}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-python36-tests.patch
+)
+
+python_prepare_all() {
+	# Disable erroneous test
+	sed -e 's:test_default_plugins_place_is_parent_dir:_&:' \
+		-i test/test_PluginFileLocator.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	distutils-r1_python_install_all
+}