1 files changed, 38 insertions, 0 deletions
diff --git a/dev-python/websocket-client/websocket-client-0.58.0-r1.ebuild b/dev-python/websocket-client/websocket-client-0.58.0-r1.ebuild
new file mode 100644
index 000000000000..9d1502563095
--- /dev/null
+++ b/dev-python/websocket-client/websocket-client-0.58.0-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{7..9} )
+
+inherit distutils-r1
+
+MY_P=${P/-/_}
+DESCRIPTION="WebSocket client for python with hybi13 support"
+HOMEPAGE="https://github.com/websocket-client/websocket-client"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~ppc64 x86 ~x64-macos"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests setup.py
+
+src_prepare() {
+	sed -i -e '1i#!/usr/bin/env python' bin/wsdump.py || die
+	distutils-r1_src_prepare
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}